/src/QueryHealer.elm at 7763db6a008a4ba3eb78077e8f46381e687cd363

-- Copyright 2026 Shota FUJI
--
-- This Source Code Form is subject to the terms of the Mozilla Public
-- License, v. 2.0. If a copy of the MPL was not distributed with this
-- file, You can obtain one at https://mozilla.org/MPL/2.0/.
--
-- SPDX-License-Identifier: MPL-2.0


module QueryHealer exposing (Model, Msg, init, update, view)

import Dict exposing (Dict)
import Dict.Any
import Html exposing (..)
import Html.Attributes exposing (..)
import Html.LivingStandard exposing (..)
import Parameters
import Parameters.Key as Key exposing (Key)
import Parameters.Parser exposing (Error(..))
import Url exposing (Url)
import Url.SearchParams as SearchParams



-- MODEL


type alias Model =
    { errors : Parameters.Parser.Errors
    , searchParams : Dict String String
    , url : Url
    }


init : Url -> Parameters.Parser.Errors -> Model
init url errors =
    { errors = errors
    , searchParams =
        url.query
            |> Maybe.map SearchParams.parse
            |> Maybe.withDefault Dict.empty
    , url = url
    }



-- UPDATE


type Msg
    = NoOp


update : Msg -> Model -> ( Model, Cmd Msg )
update msg model =
    case msg of
        NoOp ->
            ( model, Cmd.none )



-- VIEW


defaults : Dict String String
defaults =
    Dict.union
        (Parameters.toDict Parameters.default)
        Parameters.fallbackValues


row : Model -> Key -> Error -> Html Msg
row { searchParams, url } key error =
    let
        setLinkText : String -> Html msg
        setLinkText value =
            text ("Set to \"" ++ value ++ "\". ")

        withDefault =
            case Parameters.getKey key defaults of
                Just value ->
                    Dict.insert (Key.toString key) value searchParams

                Nothing ->
                    searchParams

        defaultLink =
            a
                [ slot "action"
                , href (Url.toString { url | query = Just (SearchParams.build withDefault) })
                ]
                [ setLinkText (Parameters.getKey key defaults |> Maybe.withDefault "")
                , text "(default value)"
                ]
    in
    node "x-query-healer"
        [ role "listitem" ]
        (span [ slot "key" ] [ text (Key.toLabel key) ]
            :: (case error of
                    MissingValue ->
                        [ span [ slot "description" ] [ text "Parameter is missing" ]
                        , defaultLink
                        ]

                    BelowMin min ->
                        let
                            withMin =
                                Dict.insert (Key.toString key) (String.fromFloat min) searchParams
                        in
                        [ span [ slot "description" ] [ text "Value is below the minimum." ]
                        , defaultLink
                        , a
                            [ slot "action"
                            , href (Url.toString { url | query = Just (SearchParams.build withMin) })
                            ]
                            [ setLinkText (String.fromFloat min)
                            , text "(minimum value)"
                            ]
                        ]

                    AboveMax max ->
                        let
                            withMax =
                                Dict.insert (Key.toString key) (String.fromFloat max) searchParams
                        in
                        [ span [ slot "description" ] [ text "Value exceeds the maximum." ]
                        , defaultLink
                        , a
                            [ slot "action"
                            , href (Url.toString { url | query = Just (SearchParams.build withMax) })
                            ]
                            [ setLinkText (String.fromFloat max)
                            , text "(maximum value)"
                            ]
                        ]

                    NotALength ->
                        [ span [ slot "description" ] [ text "Value is not a valid length value." ]
                        , defaultLink
                        ]

                    NotAnInt ->
                        [ span [ slot "description" ] [ text "Value is not a valid integer." ]
                        , defaultLink
                        ]

                    NonexistentVariant _ ->
                        [ span [ slot "description" ] [ text "Unrecognizable value." ]
                        , defaultLink
                        ]

                    UnsupportedParametersVersion _ ->
                        [ span [ slot "description" ] [ text "Unsupported version." ]
                        , defaultLink
                        , a
                            [ slot "action"
                            , href (Url.toString { url | query = Just (SearchParams.build (Parameters.default |> Parameters.toDict)) })
                            ]
                            [ text "Use default parameters" ]
                        ]
               )
        )


view : Model -> Html Msg
view model =
    let
        { url } =
            model
    in
    node "x-error-page"
        []
        [ h1 [ slot "title" ] [ text "Invalid Parameters" ]
        , p
            [ slot "description" ]
            [ text "This URL is not a valid URL for WWSTB."
            , text " Fix erroneous parameters or start with "
            , a
                [ href (Url.toString { url | query = Just (SearchParams.build (Parameters.default |> Parameters.toDict)) }) ]
                [ text "default parameters" ]
            , text "."
            ]
        , node "x-query-healer-items"
            [ role "list" ]
            (model.errors
                |> Dict.Any.toList
                |> List.map (\( key, error ) -> row model key error)
            )
        ]