1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87

// Copyright 2026 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

const Elm = @This();

const std = @import("std");

b: *std.Build,
elm_make: *std.Build.Step.Run,
output_js: std.Build.LazyPath,

pub const InitOptions = struct {
    /// `Debug` enables Elm's time-travel UI. `Release*` runs ClosureCompiler over
    /// built JavaScript files.
    optimize: std.builtin.OptimizeMode = .ReleaseFast,
};

pub fn init(b: *std.Build, opts: InitOptions) Elm {
    const elm_make = b.addSystemCommand(&.{ "elm", "make" });

    if (opts.optimize == .Debug) {
        elm_make.addArg("--debug");
    } else {
        elm_make.addArg("--optimize");
    }

    elm_make.expectExitCode(0);

    const output_js = elm_make.addPrefixedOutputFileArg("--output=", "elm.js");

    if (opts.optimize == .Debug) {
        return .{
            .b = b,
            .elm_make = elm_make,
            .output_js = output_js,
        };
    } else {
        const closure_compiler = b.addSystemCommand(&.{"closure-compiler"});

        closure_compiler.addPrefixedFileArg("--js=", output_js);
        const minified_js = closure_compiler.addPrefixedOutputFileArg("--js_output_file=", "elm.min.js");

        return .{
            .b = b,
            .elm_make = elm_make,
            .output_js = minified_js,
        };
    }
}

/// Add main module.
pub fn addMainElmSourceFile(self: Elm, path: std.Build.LazyPath) void {
    self.elm_make.addFileArg(path);
}

/// Add non-main Elm source code file. You have to call this for every source files but main module.
pub fn addElmSourceFile(self: Elm, path: std.Build.LazyPath) void {
    self.elm_make.addFileInput(path);
}

pub fn generateThirdPartyLicenseText(self: Elm) std.Build.LazyPath {
    const mod = self.b.createModule(.{
        .root_source_file = self.b.path("build/third_party_licenses.zig"),
        .target = self.b.graph.host,
        .optimize = .ReleaseSafe,
    });

    const exe = self.b.addExecutable(.{
        .name = "third_party_licenses",
        .root_module = mod,
        .use_llvm = false,
    });

    const run = self.b.addRunArtifact(exe);
    run.step.dependOn(&self.elm_make.step);

    run.addArg("--elm-json");
    run.addFileArg(self.b.path("elm.json"));

    run.addArg("--out");
    return run.addOutputFileArg("third-party-licenses.txt");
}