/gtk-adwaita/src/Widgets/Browse.vala at 90a7baf980dd90c0e69f8a172f3865b2d72fc51e

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
[GtkTemplate(ui = "/jp/pocka/plac/gtk-adwaita/ui/browse.ui")]
class Browse : Gtk.Box {
	public signal void loading_start();
	public signal void loading_end();

	[GtkChild]
	private unowned Gtk.Label title;

	[GtkChild]
	private unowned Gtk.Label subtitle;

	[GtkChild]
	private unowned Gtk.Box loading;

	[GtkChild]
	private unowned Gtk.Button back;

	[GtkChild]
	private unowned Gtk.ListBox items;

	[GtkChild]
	private unowned Gtk.ScrolledWindow scroller;

	private Plac.AsyncConnection? conn = null;

	private Plac.Transport.Zone? _zone = null;
	public Plac.Transport.Zone? zone {
		get { return _zone; }
		set {
			_zone = value;
			load();
		}
	}

	private Plac.Browse.Hierarchy? _hierarchy = null;
	public Plac.Browse.Hierarchy hierarchy {
		get { return _hierarchy; }
		construct set {
			if (_hierarchy != value) {
				_hierarchy = value;
				item = null;
				load();
			}
		}
	}

	private Plac.Browse.Item? item = null;

	private bool is_loading = false;

	public Browse() {
		Object();
	}

	construct {
		items.row_activated.connect((row) => {
				var item_row = (BrowseItem.Row) row;
				item = item_row.item;

				switch (item.hint) {
					case ACTION_LIST:
						var nav = (BrowseItem.Navigation) item_row.child;
						nav.open_actions();
						break;
						default:
						load();
						break;
				}
			});

		back.clicked.connect(() => {
				pop();
			});
	}

	public void start(Plac.AsyncConnection? conn) {
		this.conn = conn;
		this.load();
	}

	private void start_loading() {
		is_loading = true;
		loading_start();
		loading.visible = true;
		this.sensitive = false;
	}

	private void end_loading() {
		is_loading = false;
		loading_end();
		loading.visible = false;
		this.sensitive = true;
	}

	private void pop(bool scroll_to_top = true) {
		this.item = null;
		this.load(true, scroll_to_top);
	}

	private void load(bool pop = false, bool scroll_to_top = true) {
		if (conn == null || _hierarchy == null || is_loading) {
			return;
		}

		start_loading();
		conn.browse.begin(_hierarchy, _zone, item, pop, (obj, res) => {
				var result = conn.browse.end(res);

				if (result.code != OK) {
					GLib.log("Plac", LEVEL_WARNING, "Browse request failed: %s", result.code.to_string());
					loading.visible = false;
					return;
				}

				if (result.action != LIST) {
					GLib.log("Plac", LEVEL_WARNING, "Unexpected result action: %s", result.action.to_string());
					loading.visible = false;
					return;
				}

				var action = result.get_list_action();

				title.label = action.title;
				if (action.subtitle != null) {
					subtitle.label = action.subtitle;
					subtitle.visible = true;
				} else {
					subtitle.visible = false;
				}

				items.remove_all();
				if (scroll_to_top) {
					scroller.vadjustment.value = scroller.vadjustment.lower;
				}
				foreach (var item in action.items) {
					var row = new BrowseItem.Row(item, conn);
					var nav = (BrowseItem.Navigation) row.child;
					nav.action_selected.connect((selected_item) => {
						this.item = selected_item;
						load(false, false);
					});
					nav.actions_open.connect(() => {
						load_actions(nav, item);
					});
					nav.actions_close.connect(() => {
						this.pop(false);
					});
					items.append(row);
				}

				back.visible = action.level > 0;
				end_loading();
			});
	}

	private void load_actions(BrowseItem.Navigation target, Plac.Browse.Item item) {
		if (conn == null || _hierarchy == null || is_loading) {
			return;
		}

		conn.browse.begin(_hierarchy, _zone, item, false, (obj, res) => {
				var result = conn.browse.end(res);

				if (result.code != OK) {
					GLib.log("Plac", LEVEL_WARNING, "Browse request failed: %s", result.code.to_string());
					loading.visible = false;
					return;
				}

				if (result.action != LIST) {
					GLib.log("Plac", LEVEL_WARNING, "Unexpected result action: %s", result.action.to_string());
					loading.visible = false;
					return;
				}

				var action = result.get_list_action();

				target.set_action_items(action);
			});
	}
}
}