/core/src/application.zig at 96637ddb2bba7cb7ca361958c64495fb67f1338b

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

const builtin = @import("builtin");
const std = @import("std");

const moo = @import("moo");
const websocket = @import("websocket");

const Connection = @import("./roon/connection.zig").Connection;
const Server = @import("./server/Server.zig").Server;
const Extension = @import("./roon/extension.zig").Extension;
const PingService = @import("./roon/services/ping.zig").PingService;
const RegistryService = @import("./roon/services/registry.zig").RegistryService;
const TransportService = @import("./roon/services/transport.zig").TransportService;

const allocator = std.heap.c_allocator;

const AppExtension = Extension(.{
    .id = "jp.pocka.plac",
    .display_name = "Plac",
    .version = "0.0.0-dev",
    .publisher = "Shota FUJI",
    .email = "pockawoooh@gmail.com",
    .required_services = &.{TransportService},
    .optional_services = &.{},
    .provided_services = &.{PingService},
});

pub const Application = extern struct {
    addr: std.net.Address,
    conn: ?*Connection = null,

    /// Returns `null` on OOM.
    pub fn makeFromServer(server_ptr: ?*const Server) callconv(.C) ?*Application {
        const server = server_ptr orelse return null;
        const conn = allocator.create(Application) catch return null;

        conn.* = .{
            .addr = std.net.Address.initPosix(&server.sockaddr),
        };

        return conn;
    }

    pub fn free(self_ptr: ?*Application) callconv(.C) void {
        if (self_ptr) |self| {
            if (self.conn) |conn| {
                conn.deinit();
                allocator.destroy(conn);
            }

            allocator.destroy(self);
        }
    }

    pub const ConnectResultCode = enum(c_int) {
        ok = 0,
        unknown_error = 1,
        null_self_pointer = 2,
        out_of_memory = 3,
        registry_down = 4,
        failed_to_register = 5,
        websocket_connection_error = 6,
        listen_thread_spawn_error = 7,
    };

    pub const ConnectResult = extern struct {
        code: ConnectResultCode,

        token: ?[*:0]const u8 = null,
        token_len: usize = 0,

        pub fn free(self_ptr: ?*ConnectResult) callconv(.C) void {
            const self = self_ptr orelse return;

            if (self.token) |token| {
                allocator.free(token[0..self.token_len]);
            }

            allocator.destroy(self);
        }
    };

    /// Returns `null` when unable to allocate result struct.
    pub fn connect(
        self_ptr: ?*Application,
        saved_token: ?[*:0]const u8,
    ) callconv(.C) ?*ConnectResult {
        const result = allocator.create(ConnectResult) catch return null;

        const self = self_ptr orelse {
            result.* = .{
                .code = .null_self_pointer,
            };

            return result;
        };

        self.connectInternal(saved_token, result) catch |err| {
            result.* = .{
                .code = switch (err) {
                    error.OutOfMemory => .out_of_memory,
                    Connection.InitError.WebSocketClientCreationError, Connection.InitError.WebSocketHandshakeError => .websocket_connection_error,
                    ConnectError.RegistryInfoError => .registry_down,
                    ConnectError.RegistryRegisterError => .failed_to_register,
                    ConnectError.ListeningThreadSpawnError => .listen_thread_spawn_error,
                    else => .unknown_error,
                },
            };
        };

        return result;
    }

    const ConnectError = error{
        RegistryInfoError,
        RegistryRegisterError,
        ListeningThreadSpawnError,
    };

    fn connectInternal(
        self: *Application,
        saved_token: ?[*:0]const u8,
        result: *ConnectResult,
    ) !void {
        const conn = try allocator.create(Connection);
        conn.* = try Connection.init(allocator, self.addr);
        errdefer conn.deinit();

        conn.listen(PingService.handleRequest) catch {
            return ConnectError.ListeningThreadSpawnError;
        };

        std.log.debug("Querying registry status...", .{});
        const info = RegistryService.info(allocator, conn) catch |err| {
            std.log.err("Failed to get extension registry status: {s}", .{@errorName(err)});
            return ConnectError.RegistryInfoError;
        };
        defer info.deinit();

        const extension = AppExtension{
            .token = if (saved_token) |tok| std.mem.span(tok) else null,
        };

        std.log.debug("Registering extension {s} token...", .{if (saved_token) |_| "with" else "without"});
        const register = RegistryService.register(AppExtension, allocator, conn, extension) catch |err| {
            std.log.err("Failed to register extension: {s}", .{@errorName(err)});
            return ConnectError.RegistryRegisterError;
        };
        defer register.deinit();

        self.conn = conn;

        std.log.debug("Extension registered, application is ready", .{});

        const token = try allocator.dupeZ(u8, register.value.token);

        result.* = .{
            .code = .ok,
            .token = token.ptr,
            .token_len = token.len,
        };
    }
};