/core/src/lib.vapi at 5dc2caa934167c5095db8ef4b081e85a8d5705ed

/*
 * Copyright 2025 Shota FUJI
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 *
 * SPDX-License-Identifier: Apache-2.0
 */

[CCode (cheader_filename = "plac_core.h")]
namespace PlacCore {
	[CCode (
		cname = "plac_app_server_zone_playback_state",
		cprefix = "PLAC_APP_PLAYBACK_",
		has_type_id = false
	)]
	public enum ZonePlaybackState {
		STOPPED,
		PAUSED,
		PLAYING,
	}

	[CCode (cname = "plac_app_server_zone", free_function = "")]
	[Compact]
	public class Zone {
		[CCode (cname = "plac_cb_zone_change", has_target = true)]
		public delegate void OnChange ();

		[CCode (cname = "plac_cb_zone_remove", has_target = true)]
		public delegate void OnRemove ();

		public string id;
		public string name;
		public ZonePlaybackState playback_state;

		[CCode (cname = "plac_app_server_zone_on_change")]
		public void on_change (OnChange f);

		[CCode (cname = "plac_app_server_zone_on_remove")]
		public void on_remove (OnRemove f);
	}

	[CCode (
		cname = "plac_app_server_zone_list_loading",
		cprefix = "PLAC_APP_SERVER_ZONE_LIST_LOADING_",
		has_type_id = false
	)]
	public enum ZoneListLoading {
		NOT_LOADED,
		LOADING,
		LOADED,
		REFRESHING,
		ERR_UNEXPECTED,
		ERR_THREAD_SPAWN,
		ERR_OUT_OF_MEMORY,
		ERR_NON_SUCCESS,
	}

	[CCode (cname = "plac_app_server", free_function = "")]
	[Compact]
	public class Server {
		[CCode (cname = "plac_cb_zone_add", has_target = true)]
		public delegate void OnZoneAdd (Zone added);

		[CCode (cname = "plac_cb_zone_list_loading_change", has_target = true)]
		public delegate void OnZoneListLoadingChange ();

		public string id;
		public string name;
		public string version;
		[CCode (array_length_cname = "zones_len", array_length_type = "unsigned int")]
		public Zone[] zones;
		public ZoneListLoading zones_loading;
		public string token;

		[CCode (cname = "plac_app_server_load_zones")]
		public void load_zones ();

		[CCode (cname = "plac_app_server_on_zone_add")]
		public void on_zone_add (OnZoneAdd f);

		[CCode (cname = "plac_app_server_on_zone_list_loading_change")]
		public void on_zone_list_loading_change (OnZoneListLoadingChange f);
	}

	[CCode (cname = "plac_app_server_selector_entry", free_function = "")]
	[Compact]
	public class ServerSelectorEntry {
		public string id;
		public string name;
		public string version;
	}

	[CCode (
		cname = "plac_app_server_selector_state",
		cprefix = "PLAC_APP_SERVER_SELECTOR_",
		has_type_id = false
	)]
	public enum ServerSelectorState {
		NOT_LOADED,
		LOADING,
		LOADED,
		REFRESHING,
		ERR_UNEXPECTED,
		ERR_NETWORK_UNAVAILABLE,
		ERR_SOCKET_PERMISSION,
		ERR_OUT_OF_MEMORY,
		ERR_SOCKET,
		ERR_THREAD_SPAWN,
	}

	[CCode (cname = "plac_app_server_selector", free_function = "")]
	[Compact]
	public class ServerSelector {
		[CCode (cname = "plac_cb_server_selector_change", has_target = true)]
		public delegate void OnChange ();

		public ServerSelectorState state;
		[CCode (array_length_cname = "entries_len", array_length_type = "unsigned int")]
		public ServerSelectorEntry[] entries;

		[CCode (cname = "plac_app_server_selector_reset")]
		public void reset();

		[CCode (cname = "plac_app_server_selector_load")]
		public void load();

		[CCode (cname = "plac_app_server_selector_on_change")]
		public void on_change (OnChange f);
	}

	[CCode (
		cname = "plac_app_connection_state",
		cprefix = "PLAC_APP_CONNECTION_",
		has_type_id = false
	)]
	public enum ConnectionState {
		IDLE,
		BUSY,
		ERR_UNEXPECTED,
		ERR_NETWORK_UNAVAILABLE,
		ERR_SOCKET_PERMISSION,
		ERR_OUT_OF_MEMORY,
		ERR_SOCKET,
		ERR_REGISTRY_DOWN,
		ERR_FAILED_TO_REGISTER,
		ERR_THREAD_SPAWN,
		ERR_WEBSOCKET,
		ERR_NOT_FOUND,
	}

	[CCode (cname = "plac_app", free_function = "plac_app_destroy")]
	[Compact]
	public class App {
		[CCode (cname = "plac_cb_server_change", has_target = true)]
		public delegate void OnServerChange ();

		[CCode (cname = "plac_cb_connection_change", has_target = true)]
		public delegate void OnConnectionChange ();

		[CCode (cname = "plac_app_new")]
		public App ();

		public ServerSelector server_selector;
		public ConnectionState connection;
		public Server? server;

		[CCode (cname = "plac_app_connect")]
		public void connect(string* server_id, uint server_id_len, string? saved_token, uint saved_token_len);

		[CCode (cname = "plac_app_on_server_change")]
		public void on_server_change (OnServerChange f);

		[CCode (cname = "plac_app_on_connection_change")]
		public void on_connection_change (OnConnectionChange f);
	}
}