/features/dev/lsp.nix at 2953ef512f425f4f720553fcd92abe5a91d55443

# Copyright 2023 Shota FUJI <pockawoooh@gmail.com>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
# REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
# AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
# INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
# LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
# OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
# PERFORMANCE OF THIS SOFTWARE.
#
# SPDX-License-Identifier: 0BSD

{
  config,
  lib,
  pkgs,
  ...
}:
let
  cfg = config.features.dev.lsp;

  ls = lib.types.submodule {
    options = {
      cmd = lib.mkOption {
        type = lib.types.nullOr (lib.types.listOf lib.types.nonEmptyStr);

        description = "Launch command";

        default = null;
      };

      name = lib.mkOption {
        type = lib.types.nonEmptyStr;

        description = "Language Server Name";
      };

      rootMarkers = lib.mkOption {
        type = lib.types.nullOr (lib.types.listOf lib.types.nonEmptyStr);

        default = null;
      };

      singleFileSupport = lib.mkOption {
        type = lib.types.bool;

        default = false;
      };

      initOptions = lib.mkOption {
        type = lib.types.nullOr lib.types.nonEmptyStr;

        default = null;
      };

      settings = lib.mkOption {
        type = lib.types.nullOr lib.types.nonEmptyStr;

        default = null;
      };
    };
  };

  lsToSetupStmt =
    c:
    let
      cmd =
        if (c.cmd != null) then
          "cmd = { ${builtins.concatStringsSep ", " (builtins.map (x: "\"${x}\"") c.cmd)} },"
        else
          "";
      rootMarkers =
        if (c.rootMarkers != null) then
          "root_markers = { ${
            builtins.concatStringsSep ", " (builtins.map (x: "'${x}'") c.rootMarkers)
          } },"
        else
          "";
      initOptions =
        if (c.initOptions != null) then "init_options = { ${c.initOptions} }," else "";
      settings = if (c.settings != null) then "settings = { ${c.settings} }," else "";
    in
    ''
      vim.lsp.config('${c.name}', {
        ${cmd}
        ${rootMarkers}
        workspace_required = ${lib.trivial.boolToString (!c.singleFileSupport)},
        ${initOptions}
        ${settings}
        capabilities = {
          textDocument = {
            completion = {
              completionItem = {
                snippetSupport = false,
              }
            }
          }
        }
      })
      vim.lsp.enable('${c.name}')
    '';
in
{
  options = {
    features.dev.lsp = {
      enable = lib.mkEnableOption "LSP";

      langs = lib.mkOption {
        type = lib.types.listOf ls;

        default = [ ];
      };

      elm = lib.mkOption {
        type = ls;

        default = {
          name = "elmls";
        };
      };

      typescript = lib.mkOption {
        type = ls;

        default = {
          name = "ts_ls";
          rootMarkers = [ "tsconfig.json" ];
          initOptions = ''
            preferences = {
              includePackageJsonAutoImports = "off",
              jsxAttributeCompletionStyle = "none",
              autoImportFileExcludePatterns = { "**" },
            }
          '';
        };
      };

      deno = lib.mkOption {
        type = ls;

        default = {
          name = "denols";
          rootMarkers = [
            "deno.json"
            "deno.jsonc"
          ];
          settings = ''
            deno = {
              suggest = {
                autoImports = false,
              }
            }
          '';
        };
      };

      go = lib.mkOption {
        type = ls;

        default = {
          name = "gopls";
        };
      };

      css = lib.mkOption {
        type = ls;

        default = {
          name = "cssls";
          singleFileSupport = true;
          initOptions = ''
            provideFormatter = false
          '';
          settings = ''
            css = {
              validate = false
            }
          '';
        };
      };

      html = lib.mkOption {
        type = ls;

        default = {
          name = "html";
          singleFileSupport = true;
        };
      };

      zig = lib.mkOption {
        type = ls;

        default = {
          cmd = [
            "zls"
            "--config-path"
            "${config.xdg.configHome}/zls.json"
          ];
          name = "zls";
        };
      };

      gleam = lib.mkOption {
        type = ls;

        default = {
          name = "gleam";
          # nvim-lspconfig incorrectly have ".git" in the default root_markers.
          rootMarkers = [ "gleam.toml" ];
        };
      };

      swift = lib.mkOption {
        type = ls;

        default = {
          name = "sourcekit";
        };
      };
    };
  };

  config = {
    programs = lib.mkIf (config.features.dev.enable && cfg.enable) {
      neovim = lib.mkIf config.programs.neovim.enable {
        plugins = with pkgs.vimPlugins; [
          {
            plugin = mini-completion;
            type = "lua";
            config = builtins.readFile ./neovim/mini-completion.lua;
          }
          {
            plugin = nvim-lspconfig;
            type = "lua";

            config = builtins.concatStringsSep "\n" (
              [
                ''
                  -- Based on https://github.com/neovim/nvim-lspconfig#suggested-configuration

                  local lspconfig = require("lspconfig")

                ''
              ]
              ++ (builtins.map lsToSetupStmt cfg.langs)
              ++ [ (builtins.readFile ./neovim/lspconfig.lua) ]
            );
          }
          { plugin = luasnip; }
        ];
      };
    };

    home.packages = [
      (lib.mkIf (builtins.elem cfg.zig cfg.langs) pkgs.zls)
      (lib.mkIf (!pkgs.stdenv.isDarwin) pkgs.sourcekit-lsp)
    ];

    # zls, the Zig Language Server does not support LSP's initializationOptions
    # but their own JSON config file.
    xdg.configFile."zls.json" = {
      enable = builtins.elem cfg.zig cfg.langs;

      text = builtins.toJSON {
        enable_snippets = false;
        enable_argument_placeholders = false;
      };
    };
  };
}