1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144
145. 145
146. 146
147. 147
148. 148
149. 149
150. 150
151. 151
152. 152

# Copyright 2023 Shota FUJI <pockawoooh@gmail.com>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
# REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
# AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
# INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
# LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
# OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
# PERFORMANCE OF THIS SOFTWARE.
#
# SPDX-License-Identifier: 0BSD

{ pkgs, lib, config, ... }:
let
  cfg = config.features.scm;
in
{
  options = {
    features.scm = {
      enable = lib.mkEnableOption "SCM";
    };
  };

  config = lib.mkIf cfg.enable {
    programs.git =
      let
        difftasticConfig =
          if config.features.dev.enable then
            {
              # https://difftastic.wilfred.me.uk/git.html
              diff = {
                tool = "difftastic";
              };

              difftool = {
                prompt = false;
              };

              "difftool \"difftastic\"" = {
                cmd = ''difft "$LOCAL" "$REMOTE"'';
              };

              pager = {
                difftool = true;
              };
            }
          else
            { };
      in
      {
        enable = true;

        userName = config.features.identity.name;
        userEmail = config.features.identity.email;

        signing =
          if (config.features.identity.gpgSigningKeyId != null) then {
            key = config.features.identity.gpgSigningKeyId;
            signByDefault = true;
          } else null;

        extraConfig = {
          core = {
            editor = if config.programs.neovim.enable then "nvim" else "vim";
          };

          init = {
            defaultBranch = "master";
          };
        } // difftasticConfig;

        ignores =
          let
            # # Ignore all bazel-* symlinks. There is no full list since this can change
            # based on the name of the directory bazel is cloned into.
            bazel = [ "/bazel-*" ];

            # Swap file
            nvim = if config.programs.neovim.enable then [ ".*.swp" ] else [ ];

            # https://github.com/github/gitignore/blob/main/Global/macOS.gitignore
            darwin =
              if pkgs.stdenv.isDarwin
              then [
                ".DS_Store"
                ".AppleDouble"
                ".LSOverride"
              ]
              else [ ];
          in
          nvim ++ darwin ++ bazel;
      };

    # https://github.com/martinvonz/jj
    programs.jujutsu = {
      enable = true;

      settings = {
        user = {
          name = config.features.identity.name;
          email = config.features.identity.email;
        };

        signing = lib.mkIf (config.features.identity.gpgSigningKeyId != null) {
          behavior = "own";
          backend = "gpg";
          key = config.features.identity.gpgSigningKeyId;
        };

        ui = lib.mkIf config.features.dev.enable {
          diff = {
            tool = [ "difft" "--color=always" "$left" "$right" ];
          };
        };

        revsets = {
          log = "all()";
        };

        git = {
          private-commits = "description(regex:'\\[WIP\\]')";
        };
      };
    };

    home.packages = [
      pkgs.fossil
      (
        # Fossil derivation in Nixpkgs install bash completion only, while Fossil provides zsh's one too.
        # Creating a new derivation is so much effective compared to using `lib.overrideAttrs` because
        # of build cache.
        pkgs.stdenv.mkDerivation {
          pname = "fossil-zsh-completion";
          version = pkgs.fossil.version;

          src = pkgs.fossil.src;

          phases = [ "unpackPhase" "installPhase" ];

          nativeBuildInputs = [ pkgs.installShellFiles ];

          installPhase = ''
            installShellCompletion --zsh --name _fossil tools/fossil-autocomplete.zsh
          '';
        }
      )
    ];
  };
}