1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114

// Copyright 2025 Shota FUJI <pockawoooh@gmail.com>
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

const std = @import("std");

allocator: std.mem.Allocator,
file_path: []const u8,
class: ?[]const u8 = null,
trim_markdown_list_prefix: bool = false,

pub const InitError = error{
    IncorrectUsage,
    ShowHelp,
} || std.mem.Allocator.Error || std.fs.Dir.RealPathAllocError;

const class_arg_prefix = "--class=";

pub const helpText =
    \\,waybar-text - Watches text file and print its first line
    \\
    \\[USAGE]
    \\,waybar-text [--class=string] <FILE>
    \\
    \\[OPTIONS]
    \\--help         Print this message to stdout and exits.
    \\--class=string Set CSS class for the output text.
    \\--trim-md-list Trim markdown list prefixes from displaying text.
    \\
;

pub fn init(allocator: std.mem.Allocator) InitError!@This() {
    var iter = try std.process.ArgIterator.initWithAllocator(allocator);
    defer iter.deinit();

    // Skip program name.
    _ = iter.next();

    var first_positional_arg: ?[]const u8 = null;

    var class: ?[]const u8 = null;
    errdefer if (class) |slice| allocator.free(slice);

    var trim_markdown_list_prefix: bool = false;

    while (iter.next()) |arg| {
        if (std.mem.eql(u8, arg, "--help")) {
            return InitError.ShowHelp;
        }

        if (std.mem.startsWith(u8, arg, class_arg_prefix)) {
            if (class) |_| {
                std.log.err("--class can't be used more than once", .{});
                return InitError.IncorrectUsage;
            }

            class = try allocator.dupe(u8, arg[class_arg_prefix.len..]);
            if (class) |c| if (c.len == 0) {
                std.log.err("--class requires a value", .{});
                return InitError.IncorrectUsage;
            };

            continue;
        }

        if (std.mem.eql(u8, arg, "--trim-md-list")) {
            trim_markdown_list_prefix = true;
            continue;
        }

        if (std.mem.startsWith(u8, arg, "-")) {
            std.log.err("Unknown option: {s}", .{arg});
            return InitError.IncorrectUsage;
        }

        if (first_positional_arg) |_| {
            std.log.err("FILE can't be used more than once", .{});
            return InitError.IncorrectUsage;
        }

        first_positional_arg = arg;
    }

    const cwd = std.fs.cwd();

    const file = try cwd.realpathAlloc(allocator, first_positional_arg orelse {
        std.log.err("FILE is required", .{});
        return InitError.IncorrectUsage;
    });

    return .{
        .allocator = allocator,
        .file_path = file,
        .class = class,
        .trim_markdown_list_prefix = trim_markdown_list_prefix,
    };
}

pub fn deinit(self: *const @This()) void {
    self.allocator.free(self.file_path);
    if (self.class) |class| self.allocator.free(class);
}