1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57

// Copyright 2025 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

using GLib;

namespace TimeTracker.Widget {
	private class TimerList : Gtk.Box {
		public signal void stop(Model.Timer timer);

		public ListModel timers { get; set construct; }

		public TimerList(ListModel timers) {
			Object(timers: timers);
		}

		construct {
			var factory = new Gtk.SignalListItemFactory();
			factory.setup.connect(setup);
			factory.bind.connect(bind);

			var list = new Gtk.ListView(null, factory);
			list.hexpand = true;
			list.hexpand_set = true;
			this.append(list);

			this.bind_property("timers", list, "model", SYNC_CREATE, (_binding, from, ref to) => {
				to = new Gtk.NoSelection((ListModel) from);
			});
		}

		private void setup(Gtk.ListItemFactory _factory, Object object) {
			var list_item = (Gtk.ListItem) object;
			list_item.selectable = false;
			list_item.activatable = false;

			var row = new TimerListRow();
			row.stop.connect((timer) => {
				stop(timer);
			});
			list_item.child = row;
		}

		private void bind(Gtk.ListItemFactory _factory, Object object) {
			var list_item = (Gtk.ListItem) object;
			var timer = (Model.Timer) list_item.item;
			var row = (TimerListRow) list_item.child;

			row.timer = timer;
		}
	}
}