1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125

// Copyright 2025 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

using GLib;

namespace TimeTracker.Widget {
	private class CalendarView : Gtk.Box {
		public Model.Model model { get; construct; }
		public DateTime month { get; set construct; }

		private Gtk.Grid grid = new Gtk.Grid();
		private Gtk.Label title = new Gtk.Label("");
		private Array<CalendarCell> cells = new Array<CalendarCell>();

		public CalendarView(Model.Model model) {
			Object(
				model: model,
				month: new DateTime.now_local(),
				orientation: Gtk.Orientation.VERTICAL,
				spacing: 16
			);
		}

		construct {
			var header = new Gtk.Box(HORIZONTAL, 4);
			header.hexpand = true;
			header.margin_top = 4;
			header.margin_bottom = header.margin_top;
			header.margin_start = 8;
			header.margin_end = header.margin_start;

			var prev = new Gtk.Button();
			prev.label = "Prev";
			prev.clicked.connect(() => {
				month = month.add_months(-1);
			});
			header.append(prev);

			title.css_classes = { "numeric" };
			title.hexpand = true;
			title.hexpand_set = true;
			header.append(title);

			var next = new Gtk.Button();
			next.label = "Next";
			next.clicked.connect(() => {
				month = month.add_months(1);
			});
			header.append(next);

			this.append(header);
			this.append(grid);

			this.notify["month"].connect(() => {
				this.render();
			});

			this.render();
		}

		private void render() {
			// Ideally, this should be binding but GObject binding not working for
			// get-only property... what a half ass system.
			title.label = month.format("%Y-%m");

			foreach (var cell in cells.data) {
				grid.remove(cell);
			}
			cells = new Array<CalendarCell>();

			var first_cell = start_of_week(start_of_month(month));
			var last_cell = end_of_week(end_of_month(month));

			for (var d = first_cell; d.compare(last_cell) < 1; d = d.add_days(1)) {
				var cell = new CalendarCell(d) {
					dimmed = d.get_month() != month.get_month(),
				};
				cell.hexpand = true;
				cell.vexpand = true;
				cells.append_val(cell);
				grid.attach(
					cell,
					d.get_day_of_week() - 1,
					(int) (d.difference(first_cell) / GLib.TimeSpan.DAY / 7),
					1, 1
				);
			}
		}

		private static DateTime start_of_month(DateTime d) {
			return new DateTime(
				d.get_timezone(),
				d.get_year(), d.get_month(), 1,
				0, 0, 0
			);
		}

		private static DateTime end_of_month(DateTime d) {
			return start_of_month(d).add_months(1).add_seconds(-1);
		}

		private static DateTime start_of_day(DateTime d) {
			return new DateTime(
				d.get_timezone(),
				d.get_year(), d.get_month(), d.get_day_of_month(),
				0, 0, 0
			);
		}

		private static DateTime start_of_week(DateTime d) {
			var day_of_week = d.get_day_of_week();
			return start_of_day(d).add_days(-(day_of_week - 1));
		}

		private static DateTime end_of_week(DateTime d) {
			var day_of_week = d.get_day_of_week();
			return start_of_day(d).add_days(7 - day_of_week);
		}
	}
}