1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120

# Copyright 2026 Shota FUJI <pockawoooh@gmail.com>
# SPDX-License-Identifier: MIT

self:
{
  config,
  lib,
  pkgs,
  ...
}:
let
  yaml = pkgs.formats.yaml { };
in
{
  disabledModules = [ "services/networking/legit.nix" ];

  options = {
    services.legit = {
      enable = lib.mkEnableOption "legit";
      package = lib.mkOption {
        type = lib.types.package;
        default = self.packages.${pkgs.stdenv.system}.legit;
      };
      config = lib.mkOption {
        type = yaml.type;
        default = {
          repo.scanPath = "/var/www/git";
          meta = {
            syntaxHighlight = true;
          };
          footer = {
            poweredBy = true;
          };
          server = {
            host = "127.0.0.1";
            port = 5555;
          };
        };
        description = ''
          The contents of the configuration file for legit.
        '';

        example = lib.literalExpression ''
          {
            repo.scanPath = "/var/www/git";
            meta = {
              title = "My Projects";
              description = "My git repos";
              syntaxHighlight = true;
            };
            footer = {
              links = [
                { text = "Contact"; href = "mailto:alice@example.com"; }
              ];
              poweredBy = true;
            };
            server = {
              name = "git.example.com";
              host = "127.0.0.1";
              port = 5555;
            };
          }
        '';
      };

      user = lib.mkOption {
        type = lib.types.nonEmptyStr;
        default = "legit";
        description = "User account under which legit runs.";
      };

      group = lib.mkOption {
        type = lib.types.nonEmptyStr;
        default = "legit";
        description = "Group account under which legit runs.";
      };
    };
  };

  config =
    let
      cfg = config.services.legit;

      configFile = yaml.generate "legit.config.yaml" cfg.config;
    in
    lib.mkIf cfg.enable {
      users.groups = lib.optionalAttrs (cfg.group == "legit") { legit = { }; };

      users.users = lib.optionalAttrs (cfg.group == "legit") {
        legit = {
          group = "legit";
          isSystemUser = true;
        };
      };

      systemd.services.legit = {
        description = "web frontend for git repositories";
        after = [ "network.target" ];
        restartTriggers = [ configFile ];

        serviceConfig = {
          User = cfg.user;
          Group = cfg.group;
          Type = "simple";
          ExecStart = "${lib.getExe cfg.package} -config ${configFile}";
          Restart = "always";
        };
      };

      systemd.paths.legit-repos = {
        description = "repositories directory read by legit";
        wantedBy = [ "default.target" ];

        pathConfig = {
          PathExists = cfg.config.repo.scanPath;
          Unit = "legit.service";
        };
      };
    };
}