1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144

// Copyright 2025 Shota FUJI
//
// Licensed under the Zero-Clause BSD License or the Apache License, Version 2.0, at your option.
// You may not use, copy, modify, or distribute this file except according to those terms. You can
// find a copy of the Zero-Clause BSD License at LICENSES/0BSD.txt, and a copy of the Apache License,
// Version 2.0 at LICENSES/Apache-2.0.txt. You may also obtain a copy of the Zero-Clause BSD License
// at <https://opensource.org/license/0bsd> and a copy of the Apache License, Version 2.0 at
// <https://www.apache.org/licenses/LICENSE-2.0>
//
// SPDX-License-Identifier: 0BSD OR Apache-2.0

//! This example code sends info request and displays returned message.
//! You have to obtain target Roon Server's IP address and HTTP port.
//! An IP address is displayed in Roon's settings page.
//! HTTP port can be obtained via Roon Server Discovery. An example program
//! in [libsood](https://git.pocka.jp/libsood.git) scans and displays the port.
//! Once you got an IP address and HTTP port, supply them via `--host` and
//! `--port` arguments.

const std = @import("std");

const moo = @import("moo");
const clap = @import("clap");
const websocket = @import("websocket");

const Error = error{
    MissingHost,
    MissingPort,
};

pub fn main() !void {
    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
    defer arena.deinit();

    const allocator = arena.allocator();

    const params = comptime clap.parseParamsComptime(
        \\-p, --port <u16>  HTTP port of the Roon Server
        \\-h, --host <str>  IPv4 address of the Roon Server
        \\
    );

    var diag = clap.Diagnostic{};
    var cli = clap.parse(clap.Help, &params, clap.parsers.default, .{
        .allocator = allocator,
        .diagnostic = &diag,
    }) catch |err| {
        diag.report(std.io.getStdErr().writer(), err) catch {};
        return err;
    };
    defer cli.deinit();

    const host = cli.args.host orelse return Error.MissingHost;
    const port = cli.args.port orelse return Error.MissingPort;

    try run(allocator, host, port);
}

fn run(allocator: std.mem.Allocator, host: []const u8, port: u16) !void {
    var client = try websocket.Client.init(allocator, .{
        .port = port,
        .host = host,
    });
    defer client.deinit();

    try client.handshake("/api", .{});

    const request = try createRequest(allocator);
    defer allocator.free(request);
    try client.writeBin(request);

    try client.readTimeout(std.time.ms_per_s * 3);

    while (true) {
        const response = (try client.read()) orelse {
            std.debug.print(".", .{});
            continue;
        };
        defer client.done(response);

        try handleResponse(allocator, response.data);
        try client.close(.{});
        break;
    }
}

/// Caller owns the returned slice.
fn createRequest(allocator: std.mem.Allocator) ![]u8 {
    const meta = moo.Metadata{
        .version = 1,
        .verb = "REQUEST",
        .service = "com.roonlabs.registry:1/info",
    };

    const header = moo.WellKnownHeaders{
        .content_type = "text/plain",
        .content_length = 0,
        .request_id = 1,
    };

    const body = moo.RawBody{ .bytes = "" };

    const message_size = meta.getEncodeSize() + header.getEncodeSize() + body.getEncodeSize();

    const message = try allocator.alloc(u8, message_size);
    var fbs = std.io.fixedBufferStream(message);
    const writer = fbs.writer();

    try moo.encode(writer, meta, header, body);

    return message;
}

const InfoResponse = struct {
    core_id: []const u8,
    display_name: []const u8,
    display_version: []const u8,
};

fn handleResponse(allocator: std.mem.Allocator, message: []const u8) !void {
    const meta, const meta_ctx = try moo.Metadata.parse(message);
    const header, const header_ctx = try moo.WellKnownHeaders.parse(message, meta_ctx);
    const body = try moo.JsonBody(InfoResponse).parse(allocator, message, header_ctx, .{});
    defer body.deinit();

    std.debug.print(
        \\Metadata: {s} {s}
        \\Request ID: {d}
        \\---
        \\Core ID: {s}
        \\Name: {s}
        \\Version: {s}
        \\
    ,
        .{
            meta.verb,
            meta.service,
            header.request_id,
            body.value.core_id,
            body.value.display_name,
            body.value.display_version,
        },
    );
}