/core/src/connection.zig at 032351776e429646977c697d2f8f1adfd17cd50f

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

const std = @import("std");

const moo = @import("moo");
const websocket = @import("websocket");

const Arc = @import("./Arc.zig");
const browse = @import("./browse.zig");
const discovery = @import("./discovery.zig");
const extension = @import("./extension.zig").extension;
const image = @import("./image.zig");
const freelog = @import("./log.zig").freelog;
const BrowseService = @import("./services/BrowseService.zig");
const ImageService = @import("./services/ImageService.zig");
const PingService = @import("./services/PingService.zig");
const registry = @import("./services/registry.zig");
const TransportService = @import("./services/TransportService.zig");
const transport = @import("./transport.zig");

pub const ConnectionError = enum(c_int) {
    unknown = 0,
    closed_by_server = 1,
    out_of_memory = 2,
    unexpected_response = 3,
    network_unavailable = 4,
    network_error = 5,
};

pub const ConnectionErrorEvent = extern struct {
    const cname = "plac_connection_connection_error_event";
    const allocator = std.heap.c_allocator;

    internal: *Internal,
    code: ConnectionError,

    const Internal = struct {
        arc: Arc = .{},
    };

    pub fn make(code: ConnectionError) std.mem.Allocator.Error!*ConnectionErrorEvent {
        const internal = try allocator.create(Internal);
        errdefer allocator.destroy(internal);
        internal.* = .{};

        const self = try allocator.create(ConnectionErrorEvent);
        errdefer allocator.destroy(self);

        self.* = .{
            .internal = internal,
            .code = code,
        };

        return self;
    }

    pub fn retain(ptr: ?*ConnectionErrorEvent) callconv(.C) *ConnectionErrorEvent {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        self.internal.arc.ref();
        return self;
    }

    pub fn release(ptr: ?*ConnectionErrorEvent) callconv(.C) void {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        if (self.internal.arc.unref()) {
            freelog(self);

            allocator.destroy(self.internal);
            allocator.destroy(self);
        }
    }

    pub fn export_capi() void {
        @export(&retain, .{ .name = std.fmt.comptimePrint("{s}_retain", .{cname}) });
        @export(&release, .{ .name = std.fmt.comptimePrint("{s}_release", .{cname}) });
    }
};

pub const ConnectedEvent = extern struct {
    const cname = "plac_connection_connected_event";
    const allocator = std.heap.c_allocator;

    internal: *Internal,
    token: [*:0]const u8,

    pub const Internal = struct {
        arc: Arc = .{},
    };

    /// This function takes ownership of `token`.
    pub fn make(token: [:0]const u8) std.mem.Allocator.Error!*ConnectedEvent {
        const internal = try allocator.create(Internal);
        errdefer allocator.destroy(internal);

        internal.* = .{};

        const self = try allocator.create(ConnectedEvent);
        errdefer allocator.destroy(self);

        self.* = .{
            .internal = internal,
            .token = token.ptr,
        };

        return self;
    }

    pub fn retain(ptr: ?*ConnectedEvent) callconv(.C) *ConnectedEvent {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        self.internal.arc.ref();
        return self;
    }

    pub fn release(ptr: ?*ConnectedEvent) callconv(.C) void {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        if (self.internal.arc.unref()) {
            freelog(self);

            allocator.free(std.mem.span(self.token));
            allocator.destroy(self.internal);
            allocator.destroy(self);
        }
    }

    pub fn export_capi() void {
        @export(&retain, .{ .name = std.fmt.comptimePrint("{s}_retain", .{cname}) });
        @export(&release, .{ .name = std.fmt.comptimePrint("{s}_release", .{cname}) });
    }
};

pub const Event = extern struct {
    const cname = "plac_connection_event";
    const allocator = std.heap.c_allocator;

    pub const Kind = enum(c_int) {
        connection_error = 0,
        connected = 1,
        zone_list = 10,
    };

    internal: *Internal,
    kind: Kind,

    pub const Internal = struct {
        const Payload = union(Kind) {
            connection_error: *ConnectionErrorEvent,
            connected: *ConnectedEvent,
            zone_list: *transport.ZoneListEvent,
        };

        payload: Payload,

        arc: Arc = .{},
    };

    pub fn makeConnectionError(err: anyerror) std.mem.Allocator.Error!*Event {
        const internal = try allocator.create(Internal);
        errdefer allocator.destroy(internal);

        const connection_error = try ConnectionErrorEvent.make(switch (err) {
            error.OutOfMemory => .out_of_memory,
            error.NetworkUnavailable => .network_unavailable,
            error.SocketError, error.SocketPermissionDenied => .network_error,
            error.RequestIdMismatch => .unexpected_response,
            error.ClosedByServer, error.ReadClosedConnection => .closed_by_server,
            else => .unknown,
        });
        errdefer connection_error.release();

        internal.* = .{
            .payload = .{ .connection_error = connection_error.retain() },
        };

        const self = try allocator.create(Event);
        errdefer allocator.destroy(self);

        self.* = .{
            .internal = internal,
            .kind = .connection_error,
        };

        return self;
    }

    /// This function takes ownership of `token`.
    pub fn makeConnected(token: [:0]const u8) std.mem.Allocator.Error!*Event {
        const internal = try allocator.create(Internal);
        errdefer allocator.destroy(internal);

        const connected = try ConnectedEvent.make(token);
        errdefer connected.release();

        internal.* = .{
            .payload = .{ .connected = connected.retain() },
        };

        const self = try allocator.create(Event);
        errdefer allocator.destroy(self);

        self.* = .{
            .internal = internal,
            .kind = .connected,
        };

        return self;
    }

    pub fn makeZoneListFromInitial(
        res: *const TransportService.SubscribeZoneChanges.InitialResponse,
    ) std.mem.Allocator.Error!*Event {
        const internal = try allocator.create(Internal);
        errdefer allocator.destroy(internal);

        const zone_list = try transport.ZoneListEvent.makeFromInitial(res);
        errdefer zone_list.release();

        internal.* = .{
            .payload = .{ .zone_list = zone_list.retain() },
        };

        const self = try allocator.create(Event);
        errdefer allocator.destroy(self);

        self.* = .{
            .internal = internal,
            .kind = .zone_list,
        };

        return self;
    }

    pub fn makeZoneListFromChanges(
        res: *const TransportService.SubscribeZoneChanges.Response,
    ) std.mem.Allocator.Error!*Event {
        const internal = try allocator.create(Internal);
        errdefer allocator.destroy(internal);

        const zone_list = try transport.ZoneListEvent.makeFromChanges(res);
        errdefer zone_list.release();

        internal.* = .{
            .payload = .{ .zone_list = zone_list.retain() },
        };

        const self = try allocator.create(Event);
        errdefer allocator.destroy(self);

        self.* = .{
            .internal = internal,
            .kind = .zone_list,
        };

        return self;
    }

    pub fn retain(ptr: ?*Event) callconv(.C) *Event {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        self.internal.arc.ref();
        return self;
    }

    pub fn release(ptr: ?*Event) callconv(.C) void {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        if (self.internal.arc.unref()) {
            freelog(self);

            switch (self.internal.payload) {
                .connection_error => |ev| ev.release(),
                .connected => |ev| ev.release(),
                .zone_list => |ev| ev.release(),
            }

            allocator.destroy(self.internal);
            allocator.destroy(self);
        }
    }

    fn exportEventCastFunction(comptime TargetEvent: type, comptime kind: Kind) void {
        const Caster = struct {
            pub const fn_name = std.fmt.comptimePrint("{s}_get_{s}_event", .{ cname, @tagName(kind) });

            pub fn cast(ptr: ?*Event) callconv(.C) *TargetEvent {
                const self = ptr orelse @panic(
                    std.fmt.comptimePrint("Received null pointer on {s}", .{fn_name}),
                );

                if (self.internal.payload == kind) {
                    return @field(self.internal.payload, @tagName(kind)).retain();
                }

                std.log.err("{s} called on {s}", .{ fn_name, @tagName(self.internal.payload) });
                unreachable;
            }
        };

        @export(&Caster.cast, .{ .name = Caster.fn_name });
    }

    pub fn export_capi() void {
        @export(&retain, .{ .name = std.fmt.comptimePrint("{s}_retain", .{cname}) });
        @export(&release, .{ .name = std.fmt.comptimePrint("{s}_release", .{cname}) });

        Event.exportEventCastFunction(ConnectionErrorEvent, .connection_error);
        Event.exportEventCastFunction(ConnectedEvent, .connected);
        Event.exportEventCastFunction(transport.ZoneListEvent, .zone_list);
    }
};

fn Listener(comptime T: type, timeout_ms: usize) type {
    return struct {
        wrote: std.Thread.ResetEvent = .{},
        data: ?T = null,

        pub fn listen(self: *@This()) error{Timeout}!T {
            try self.wrote.timedWait(timeout_ms * std.time.ns_per_ms);
            return self.data orelse @panic("Set Listener.wrote before writing data");
        }

        pub fn write(self: *@This(), data: T) void {
            self.data = data;
            self.wrote.set();
        }
    };
}

fn JsonResponseListener(comptime T: type, timeout_ms: usize) type {
    return Listener(moo.JsonBody(T), timeout_ms);
}

pub const Connection = extern struct {
    const cname = "plac_connection";
    const allocator = std.heap.c_allocator;

    const BrowseListener = JsonResponseListener(BrowseService.Browse.Response, 5_000);
    const LoadListener = JsonResponseListener(BrowseService.Load.Response, 5_000);
    const ControlListener = Listener(transport.ControlResultCode, 3_000);
    const SeekListener = Listener(transport.SeekResultCode, 2_000);
    const ChangeVolumeListener = Listener(transport.VolumeControlResultCode, 2_000);

    const ImageDownloader = image.Downloader(.{});

    internal: *Internal,

    pub const Internal = struct {
        tsa: std.heap.ThreadSafeAllocator = .{ .child_allocator = allocator },
        server: *discovery.Server,
        ws: ?websocket.Client = null,
        request_id: u64 = 0,
        request_id_lock: std.Thread.Mutex = .{},
        subscription_id: u64 = 0,
        host: []const u8,
        zone_subscription_request_id: ?u64 = null,
        arc: Arc = .{},
        saved_token: ?[]const u8 = null,
        browse_listeners: std.AutoHashMap(u64, BrowseListener),
        load_listeners: std.AutoHashMap(u64, LoadListener),
        image_downloads: ImageDownloader,
        control_events: std.AutoHashMap(u64, ControlListener),
        seek_events: std.AutoHashMap(u64, SeekListener),
        change_volume_events: std.AutoHashMap(u64, ChangeVolumeListener),

        fn init(server: *discovery.Server, token: ?[]const u8) !Internal {
            var addr = std.ArrayList(u8).init(allocator);
            defer addr.deinit();

            try addr.writer().print("{}", .{server.internal.address});

            const addr_string = try addr.toOwnedSlice();
            defer allocator.free(addr_string);

            // Zig std always prints "<addr>:<port>" for IPv4 and IPv6
            const port_start = std.mem.lastIndexOfScalar(u8, addr_string, ':') orelse {
                unreachable;
            };

            const host = try allocator.dupe(u8, addr_string[0..port_start]);
            errdefer allocator.free(host);

            const saved_token = if (token) |t| try allocator.dupe(u8, t) else null;
            errdefer if (saved_token) |t| {
                allocator.free(t);
            };

            return .{
                .server = server.retain(),
                .host = host,
                .saved_token = saved_token,
                .browse_listeners = undefined,
                .load_listeners = undefined,
                .image_downloads = undefined,
                .control_events = undefined,
                .seek_events = undefined,
                .change_volume_events = undefined,
            };
        }

        fn initListeners(self: *Internal) void {
            self.browse_listeners = std.AutoHashMap(u64, BrowseListener).init(allocator);
            self.load_listeners = std.AutoHashMap(u64, LoadListener).init(allocator);
            self.image_downloads = ImageDownloader.init(self.tsa.allocator());
            self.control_events = std.AutoHashMap(u64, ControlListener).init(allocator);
            self.seek_events = std.AutoHashMap(u64, SeekListener).init(allocator);
            self.change_volume_events = std.AutoHashMap(u64, ChangeVolumeListener).init(allocator);
        }

        fn deinitListeners(self: *Internal) void {
            self.browse_listeners.deinit();
            self.load_listeners.deinit();

            self.image_downloads.deinit();
            self.control_events.deinit();
            self.seek_events.deinit();
            self.change_volume_events.deinit();
        }

        fn deinit(self: *Internal) void {
            self.deinitListeners();

            if (self.ws) |*ws| {
                ws.deinit();
            }

            if (self.saved_token) |saved_token| {
                allocator.free(saved_token);
            }

            allocator.free(self.host);
            self.server.release();
        }
    };

    fn getRequestId(self: *Connection) u64 {
        self.internal.request_id_lock.lock();
        defer self.internal.request_id_lock.unlock();

        const current = self.internal.request_id;
        self.internal.request_id += 1;
        return current;
    }

    pub fn make(server_ptr: ?*discovery.Server, token: ?[*:0]const u8) callconv(.C) ?*Connection {
        const server = server_ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        const self = allocator.create(Connection) catch return null;

        const internal = allocator.create(Internal) catch {
            allocator.destroy(self);
            return null;
        };

        internal.* = Internal.init(server, if (token) |t| std.mem.span(t) else null) catch |err| {
            std.log.err("Unable to establish connection to Roon Server: {s}", .{@errorName(err)});
            allocator.destroy(internal);
            allocator.destroy(self);
            return null;
        };

        self.* = .{ .internal = internal };

        internal.arc.ref();

        return self;
    }

    pub fn retain(ptr: ?*Connection) callconv(.C) *Connection {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        self.internal.arc.ref();
        return self;
    }

    pub fn release(ptr: ?*Connection) callconv(.C) void {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );
        if (self.internal.arc.unref()) {
            freelog(self);

            self.internal.deinit();
            allocator.destroy(self.internal);
            allocator.destroy(self);
        }
    }

    pub fn disconnect(ptr: ?*Connection) void {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        if (self.internal.ws) |*ws| {
            std.log.debug("Closing WebSocket connection...", .{});

            // websocket.zig cannot properly close connection, when using unmanaged read.
            // As a workaround, we use manual termination snippet from:
            // https://github.com/karlseguin/websocket.zig/issues/46
            std.posix.shutdown(ws.stream.stream.handle, .both) catch |err| {
                std.log.warn("WebSocket shutdown failed, ignoring: {s}", .{@errorName(err)});
            };
            std.posix.close(ws.stream.stream.handle);
            ws.deinit();
            self.internal.ws = null;
        }

        self.internal.deinitListeners();
    }

    pub fn getEvent(ptr: ?*Connection) callconv(.C) ?*Event {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        var ws = self.internal.ws orelse {
            const new_token = self.connect(self.internal.saved_token) catch |err| {
                std.log.err("Unable to connect: {s}", .{@errorName(err)});
                const event = Event.makeConnectionError(err) catch |make_err| {
                    std.log.err("Unable to compose {s} event: {s}", .{
                        @tagName(Event.Kind.connection_error),
                        @errorName(make_err),
                    });
                    return null;
                };
                return event.retain();
            };

            const event = Event.makeConnected(new_token) catch |err| {
                std.log.err("Unable to compose {s} event: {s}", .{
                    @tagName(Event.Kind.connected),
                    @errorName(err),
                });
                return null;
            };
            return event.retain();
        };

        while (true) {
            const meta, const header_ctx, const msg = readMessage(&ws) catch |err| {
                if (err == error.ReadClosedConnection) {
                    std.log.debug("WebSocket connection is closed", .{});
                    self.disconnect();
                } else {
                    std.log.err("Failed to read a message: {s}", .{@errorName(err)});
                }
                const event = Event.makeConnectionError(err) catch |make_err| {
                    std.log.err("Unable to compose {s} event: {s}", .{
                        @tagName(Event.Kind.connection_error),
                        @errorName(make_err),
                    });
                    return null;
                };
                return event.retain();
            };
            defer ws.done(msg);

            const header: moo.NoBodyHeaders, _ = moo.NoBodyHeaders.parse(msg.data, header_ctx) catch |err| {
                std.log.err("Invalid MOO message header: {s}", .{@errorName(err)});
                continue;
            };

            if (self.internal.zone_subscription_request_id) |req_id| {
                if (header.request_id == req_id) {
                    if (std.mem.eql(u8, meta.service, "Subscribed")) {
                        const res = TransportService.SubscribeZoneChanges.initialResponse(
                            allocator,
                            header_ctx,
                            msg.data,
                        ) catch |err| {
                            std.log.err(
                                "Received unexpected zone subscription response: {s}",
                                .{@errorName(err)},
                            );
                            continue;
                        };
                        defer res.deinit();

                        const event = Event.makeZoneListFromInitial(res.value) catch |make_err| {
                            std.log.err("Unable to compose {s} event: {s}", .{
                                @tagName(Event.Kind.zone_list),
                                @errorName(make_err),
                            });
                            return null;
                        };
                        return event.retain();
                    }

                    if (std.mem.eql(u8, meta.service, "Changed")) {
                        const res = TransportService.SubscribeZoneChanges.response(
                            allocator,
                            header_ctx,
                            msg.data,
                        ) catch |err| {
                            std.log.err(
                                "Received unexpected zone change response: {s}",
                                .{@errorName(err)},
                            );
                            continue;
                        };
                        defer res.deinit();

                        const event = Event.makeZoneListFromChanges(res.value) catch |err| {
                            std.log.err("Unable to compose {s} event: {s}", .{
                                @tagName(Event.Kind.zone_list),
                                @errorName(err),
                            });
                            return null;
                        };
                        return event.retain();
                    }

                    if (std.mem.eql(u8, meta.service, "Unsubscribed")) {
                        self.internal.zone_subscription_request_id = null;
                        // TODO: Return unsubscribed event
                        continue;
                    }

                    std.log.warn("Unknown response received for zone subscription: {s}", .{
                        meta.service,
                    });
                    continue;
                }
            }

            if (self.internal.browse_listeners.getEntry(header.request_id)) |entry| {
                std.log.debug("Received /browse response (ID={d})", .{header.request_id});

                const res = BrowseService.Browse.Response.parse(
                    allocator,
                    &meta,
                    header_ctx,
                    msg.data,
                ) catch |err| {
                    std.log.err("Received unexpected browse response: {s}", .{@errorName(err)});
                    continue;
                };

                entry.value_ptr.write(res);
                continue;
            }

            if (self.internal.load_listeners.getEntry(header.request_id)) |entry| {
                std.log.debug("Received /load response (ID={d})", .{header.request_id});

                const res = BrowseService.Load.Response.parse(
                    allocator,
                    &meta,
                    header_ctx,
                    msg.data,
                ) catch |err| {
                    std.log.err("Received unexpected load response: {s}", .{@errorName(err)});
                    continue;
                };

                entry.value_ptr.write(res);
                continue;
            }

            if (self.internal.control_events.getEntry(header.request_id)) |entry| {
                std.log.debug("Received /control response (ID={d})", .{header.request_id});

                entry.value_ptr.write(
                    if (std.mem.eql(u8, "Success", meta.service)) .ok else .server_error,
                );
                continue;
            }

            if (self.internal.seek_events.getEntry(header.request_id)) |entry| {
                std.log.debug("Received /seek response (ID={d})", .{header.request_id});

                entry.value_ptr.write(code: {
                    _ = TransportService.Seek.Response.decode(&meta) catch {
                        break :code .server_error;
                    };

                    break :code .ok;
                });
                continue;
            }

            if (self.internal.change_volume_events.getEntry(header.request_id)) |entry| {
                std.log.debug("Received /change_volume response (ID={d})", .{header.request_id});

                entry.value_ptr.write(code: {
                    _ = TransportService.ChangeVolume.Response.decode(&meta) catch {
                        break :code .server_error;
                    };

                    break :code .ok;
                });
                continue;
            }

            std.log.warn("Unhandle message on {s}", .{meta.service});
            std.log.debug("{s}", .{msg.data});
        }
    }

    const ReadError = error{
        ClosedByServer,
        ReadClosedConnection,
        RequestIdMismatch,
    };

    /// Returns a token. Caller owns the returned memory.
    fn connect(self: *Connection, token: ?[]const u8) ![:0]const u8 {
        std.log.debug(
            "Establishing WebSocket connection to {}...",
            .{self.internal.server.internal.address},
        );

        self.internal.initListeners();
        errdefer self.internal.deinitListeners();

        var ws = try websocket.Client.init(allocator, .{
            .host = self.internal.host,
            .port = self.internal.server.internal.address.getPort(),
            .max_size = std.math.maxInt(u32),
        });
        errdefer ws.deinit();

        std.log.debug("Performing WebSocket handshake...", .{});
        try ws.handshake("/api", .{ .timeout_ms = 1_000 });

        var request_id: u64 = 0;

        {
            {
                std.log.debug("Checking server status...", .{});
                const req = try registry.RegistryService.Info.request(allocator, request_id);
                defer allocator.free(req);
                try ws.writeBin(req);
            }

            _, const header_ctx, const msg = try readMessage(&ws);
            defer ws.done(msg);

            const header: moo.NoBodyHeaders, _ = try moo.NoBodyHeaders.parse(msg.data, header_ctx);
            if (header.request_id != request_id) {
                return ReadError.RequestIdMismatch;
            }

            const res = try registry.RegistryService.Info.response(
                allocator,
                header_ctx,
                msg.data,
            );
            defer res.deinit();

            request_id += 1;
        }

        const new_token = new_token: {
            {
                std.log.debug("Registering extension...", .{});
                const req = try registry.RegistryService.Register.request(
                    allocator,
                    request_id,
                    &extension,
                    token,
                );
                defer allocator.free(req);
                try ws.writeBin(req);
            }

            const meta, const header_ctx, const msg = try readMessage(&ws);
            defer ws.done(msg);

            const header: moo.NoBodyHeaders, _ = try moo.NoBodyHeaders.parse(msg.data, header_ctx);
            if (header.request_id != request_id) {
                return ReadError.RequestIdMismatch;
            }

            const res = try registry.RegistryService.Register.response(
                allocator,
                &meta,
                header_ctx,
                msg.data,
            );
            defer res.deinit();

            request_id += 1;

            break :new_token try allocator.dupeZ(u8, res.value.token);
        };

        self.internal.request_id = request_id;
        self.internal.ws = ws;

        return new_token;
    }

    /// Caller is responsible for closing message by calling `ws.done()`.
    fn readMessage(ws: *websocket.Client) !struct {
        moo.Metadata,
        moo.HeaderParsingContext,
        websocket.Message,
    } {
        while (true) {
            const msg = ws.read() catch |err| {
                switch (err) {
                    error.Closed => return ReadError.ReadClosedConnection,
                    else => {
                        std.log.warn("Unable to read WebSocket message: {s}", .{@errorName(err)});
                        continue;
                    },
                }
            } orelse unreachable;

            switch (msg.type) {
                // NOTE: roon-node-api does not check whether message is binaryType.
                .text, .binary => {
                    const meta, const header_ctx = moo.Metadata.parse(msg.data) catch |err| {
                        std.log.warn("Failed to parse MOO metadata: {s}", .{@errorName(err)});
                        continue;
                    };

                    if (std.mem.eql(u8, PingService.ping_id, meta.service)) {
                        writePong(ws, header_ctx, msg.data) catch |err| {
                            std.log.warn(
                                "Failed to respond to ping request: {s}",
                                .{@errorName(err)},
                            );
                        };
                        continue;
                    }

                    return .{ meta, header_ctx, msg };
                },
                .ping => ws.writePong(msg.data) catch |err| {
                    std.log.warn("Failed to respond to ping: {s}", .{@errorName(err)});
                },
                .pong => {},
                .close => return ReadError.ClosedByServer,
            }
        }
    }

    fn writePong(
        ws: *websocket.Client,
        header_ctx: moo.HeaderParsingContext,
        message: []const u8,
    ) !void {
        var buffer = std.ArrayList(u8).init(allocator);
        defer buffer.deinit();

        try PingService.ping(buffer.writer(), header_ctx, message);

        try ws.writeBin(buffer.items);
    }

    pub fn subscribeZones(ptr: ?*Connection) callconv(.C) void {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        var ws = self.internal.ws orelse {
            std.log.err("{s}_{s} called, but WebSocket connection is not ready", .{ cname, @src().fn_name });
            return;
        };

        const req_id = self.getRequestId();

        const sub_id = self.internal.subscription_id;
        self.internal.subscription_id += 1;

        {
            std.log.debug("Subscribing to zone changes...", .{});
            const req = TransportService.SubscribeZoneChanges.request(
                allocator,
                req_id,
                sub_id,
            ) catch |err| {
                std.log.err("Unable to compose zone subscription request: {s}", .{@errorName(err)});
                return;
            };
            defer allocator.free(req);

            ws.writeBin(req) catch |err| {
                std.log.err("Unable to write subscription request: {s}", .{@errorName(err)});
                return;
            };
        }

        self.internal.zone_subscription_request_id = req_id;
    }

    pub fn control(
        ptr: ?*Connection,
        zone_ptr: ?*transport.Zone,
        action: transport.Action,
    ) callconv(.C) transport.ControlResultCode {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        var zone = zone_ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        _ = zone.retain();
        defer zone.release();

        var ws = self.internal.ws orelse {
            std.log.err("{s}_{s} called, but WebSocket connection is not ready", .{ cname, @src().fn_name });
            return .closed;
        };

        const req_id = self.getRequestId();

        std.log.debug("Sending control request... (ID={d})", .{req_id});
        const kind = control: {
            if (action.next) {
                break :control TransportService.Control.next;
            }

            if (action.prev) {
                break :control TransportService.Control.previous;
            }

            if (action.pause) {
                break :control TransportService.Control.pause;
            }

            if (action.play) {
                break :control TransportService.Control.play;
            }

            const action_num: u16 = @bitCast(action);

            std.log.err(
                "action parameter has no effective bit turned on at {s}_{s}: {b}",
                .{ cname, @src().fn_name, action_num },
            );
            return .no_action_bit_set;
        };

        const req = kind.request(allocator, req_id, std.mem.span(zone.id)) catch |err| {
            std.log.err("Unable to compose control request: {s}", .{@errorName(err)});
            return .unknown_error;
        };
        defer allocator.free(req);

        var entry = self.internal.control_events.getOrPut(req_id) catch |err| {
            std.log.err("Unable to set listener for control response: {s}", .{@errorName(err)});
            return .unknown_error;
        };
        entry.value_ptr.* = .{};
        defer _ = self.internal.control_events.remove(req_id);

        ws.writeBin(req) catch |err| {
            std.log.err("Unable to write control request: {s}", .{@errorName(err)});
            return .failed_to_send;
        };

        return entry.value_ptr.listen() catch {
            return .timeout;
        };
    }

    pub fn seek(
        ptr: ?*Connection,
        zone_ptr: ?*transport.Zone,
        seconds: i64,
    ) callconv(.C) transport.SeekResultCode {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        var zone = zone_ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        _ = zone.retain();
        defer zone.release();

        var ws = self.internal.ws orelse {
            std.log.err("{s}_{s} called, but WebSocket connection is not ready", .{ cname, @src().fn_name });
            return .closed;
        };

        const req_id = self.getRequestId();

        std.log.debug("Sending seek request...", .{});

        const req = TransportService.Seek.Request{
            .zone_or_output_id = std.mem.span(zone.id),
            .how = .absolute,
            .seconds = seconds,
        };
        const req_msg = req.encode(allocator, req_id) catch |err| {
            std.log.err("Unable to compose seek request: {s}", .{@errorName(err)});
            return .unknown_error;
        };
        defer allocator.free(req_msg);

        var entry = self.internal.seek_events.getOrPut(req_id) catch |err| {
            std.log.err("Unable to set listener for seek response: {s}", .{@errorName(err)});
            return .unknown_error;
        };
        entry.value_ptr.* = .{};
        defer _ = self.internal.seek_events.remove(req_id);

        ws.writeBin(req_msg) catch |err| {
            std.log.err("Unable to write seek request: {s}", .{@errorName(err)});
            return .failed_to_send;
        };

        return entry.value_ptr.listen() catch {
            return .timeout;
        };
    }

    pub fn increaseVolume(
        ptr: ?*Connection,
        output_ptr: ?*transport.Output,
    ) callconv(.C) transport.VolumeControlResultCode {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        var output = output_ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        _ = output.retain();
        defer output.release();

        var ws = self.internal.ws orelse {
            std.log.err("{s}_{s} called, but WebSocket connection is not ready", .{ cname, @src().fn_name });
            return .closed;
        };

        const req_id = self.getRequestId();

        std.log.debug("Sending volume increase request...(ID={d})", .{req_id});

        const req = TransportService.ChangeVolume.Request{
            .output_id = std.mem.span(output.id),
            .how = .relative,
            .value = if (output.is_incremental_volume) 1.0 else output.volume.step,
        };
        const req_msg = req.encode(allocator, req_id) catch |err| {
            std.log.err("Unable to compose volume increase request: {s}", .{@errorName(err)});
            return .unknown_error;
        };
        defer allocator.free(req_msg);

        var entry = self.internal.change_volume_events.getOrPut(req_id) catch |err| {
            std.log.err("Unable to set listener for volume increase response: {s}", .{@errorName(err)});
            return .out_of_memory;
        };
        entry.value_ptr.* = .{};
        defer _ = self.internal.change_volume_events.remove(req_id);

        ws.writeBin(req_msg) catch |err| {
            std.log.err("Unable to write volume increase request: {s}", .{@errorName(err)});
            return .failed_to_send;
        };

        return entry.value_ptr.listen() catch {
            return .timeout;
        };
    }

    pub fn decreaseVolume(
        ptr: ?*Connection,
        output_ptr: ?*transport.Output,
    ) callconv(.C) transport.VolumeControlResultCode {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        var output = output_ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        _ = output.retain();
        defer output.release();

        var ws = self.internal.ws orelse {
            std.log.err("{s}_{s} called, but WebSocket connection is not ready", .{ cname, @src().fn_name });
            return .closed;
        };

        const req_id = self.getRequestId();

        std.log.debug("Sending volume decrease request...(ID={d})", .{req_id});

        const req = TransportService.ChangeVolume.Request{
            .output_id = std.mem.span(output.id),
            .how = .relative,
            .value = if (output.is_incremental_volume) -1.0 else -output.volume.step,
        };
        const req_msg = req.encode(allocator, req_id) catch |err| {
            std.log.err("Unable to compose volume decrease request: {s}", .{@errorName(err)});
            return .unknown_error;
        };
        defer allocator.free(req_msg);

        var entry = self.internal.change_volume_events.getOrPut(req_id) catch |err| {
            std.log.err("Unable to set listener for volume decrease response: {s}", .{@errorName(err)});
            return .out_of_memory;
        };
        entry.value_ptr.* = .{};
        defer _ = self.internal.change_volume_events.remove(req_id);

        ws.writeBin(req_msg) catch |err| {
            std.log.err("Unable to write volume decrease request: {s}", .{@errorName(err)});
            return .failed_to_send;
        };

        return entry.value_ptr.listen() catch {
            return .timeout;
        };
    }

    pub fn changeVolume(
        ptr: ?*Connection,
        output_ptr: ?*transport.Output,
        abs_value: f64,
    ) callconv(.C) transport.VolumeControlResultCode {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        var output = output_ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        _ = output.retain();
        defer output.release();

        var ws = self.internal.ws orelse {
            std.log.err("{s}_{s} called, but WebSocket connection is not ready", .{ cname, @src().fn_name });
            return .closed;
        };

        const req_id = self.getRequestId();

        std.log.debug("Sending volume change request...(ID={d})", .{req_id});

        const req = TransportService.ChangeVolume.Request{
            .output_id = std.mem.span(output.id),
            .how = .absolute,
            .value = abs_value,
        };
        const req_msg = req.encode(allocator, req_id) catch |err| {
            std.log.err("Unable to compose volume change request: {s}", .{@errorName(err)});
            return .unknown_error;
        };
        defer allocator.free(req_msg);

        var entry = self.internal.change_volume_events.getOrPut(req_id) catch |err| {
            std.log.err("Unable to set listener for volume change response: {s}", .{@errorName(err)});
            return .out_of_memory;
        };
        entry.value_ptr.* = .{};
        defer _ = self.internal.change_volume_events.remove(req_id);

        ws.writeBin(req_msg) catch |err| {
            std.log.err("Unable to write volume change request: {s}", .{@errorName(err)});
            return .failed_to_send;
        };

        return entry.value_ptr.listen() catch {
            return .timeout;
        };
    }

    pub fn requestBrowse(
        ptr: ?*Connection,
        hierarchy: browse.Hierarchy,
        zone: ?*transport.Zone,
        item: ?*browse.Item,
        pop: bool,
    ) callconv(.C) ?*browse.Result {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        if (zone) |z| _ = z.retain();
        defer if (zone) |z| z.release();

        if (item) |i| _ = i.retain();
        defer if (item) |i| i.release();

        var ws = self.internal.ws orelse {
            std.log.err("{s}_{s} called, but WebSocket connection is not ready", .{ cname, @src().fn_name });
            return browse.Result.makeRetainedError(.closed) catch null;
        };

        const req_id = self.getRequestId();

        std.log.debug("Sending browse request...", .{});
        const req = BrowseService.Browse.Request{
            .hierarchy = @tagName(hierarchy),
            .zone_or_output_id = if (zone) |z| std.mem.span(z.id) else null,
            .item_key = if (item) |i| if (i.item_key) |key| std.mem.span(key) else null else null,
            .pop_all = item == null and !pop,
            .pop_levels = if (pop) 1 else null,
        };

        const req_msg = req.encode(allocator, req_id) catch |err| {
            std.log.err("Unable to compose browse request: {s}", .{@errorName(err)});
            return browse.Result.makeRetainedError(.unknown_error) catch null;
        };
        defer allocator.free(req_msg);

        var entry = self.internal.browse_listeners.getOrPut(req_id) catch |err| {
            std.log.err("Unable to set listener for browse response: {s}", .{@errorName(err)});
            return browse.Result.makeRetainedError(.unknown_error) catch null;
        };
        entry.value_ptr.* = .{};
        defer _ = self.internal.browse_listeners.remove(req_id);

        ws.writeBin(req_msg) catch |err| {
            std.log.err("Unable to write browse request: {s}", .{@errorName(err)});
            return browse.Result.makeRetainedError(.failed_to_send) catch null;
        };

        std.log.debug("Sent browse request (ID={d})", .{req_id});

        const resp = entry.value_ptr.listen() catch {
            std.log.err("Browse request timeout", .{});
            return browse.Result.makeRetainedError(.timeout) catch null;
        };
        defer resp.deinit();

        switch (resp.value.action) {
            .message => {
                const message = resp.value.message orelse {
                    std.log.err("Got `message` action, but `message` property is missing", .{});
                    return browse.Result.makeRetainedError(.missing_property) catch null;
                };

                if (resp.value.is_error orelse false) {
                    const action = browse.ErrorMessageAction.make(message) catch {
                        return browse.Result.makeRetainedError(.out_of_memory) catch null;
                    };
                    return browse.Result.makeRetained(.{ .error_message = action }) catch null;
                } else {
                    const action = browse.MessageAction.make(message) catch {
                        return browse.Result.makeRetainedError(.out_of_memory) catch null;
                    };
                    return browse.Result.makeRetained(.{ .message = action }) catch null;
                }
            },
            .replace_item => {
                const replace_item = resp.value.item orelse {
                    std.log.err("Got `replace_item` action, but `item` property is missing", .{});
                    return browse.Result.makeRetainedError(.missing_property) catch null;
                };

                const action = browse.ReplaceItemAction.make(&replace_item) catch {
                    return browse.Result.makeRetainedError(.out_of_memory) catch null;
                };
                return browse.Result.makeRetained(.{ .replace_item = action }) catch null;
            },
            .remove_item => {
                return browse.Result.makeRetained(.remove_item) catch null;
            },
            .list => {
                const list = resp.value.list orelse {
                    std.log.err("Got `list` action, but `list` property is missing", .{});
                    return browse.Result.makeRetainedError(.missing_property) catch null;
                };

                const load_req = BrowseService.Load.Request{
                    .hierarchy = @tagName(hierarchy),
                    .count = std.math.maxInt(u16),
                    .level = list.level,
                };

                const load_req_id = self.internal.request_id;
                self.internal.request_id += 1;

                const load_req_msg = load_req.encode(allocator, load_req_id) catch |err| {
                    std.log.err("Unable to compose load request: {s}", .{@errorName(err)});
                    return browse.Result.makeRetainedError(.unknown_error) catch null;
                };
                defer allocator.free(load_req_msg);

                var load_entry = self.internal.load_listeners.getOrPut(load_req_id) catch |err| {
                    std.log.err("Unable to set listener for load response: {s}", .{@errorName(err)});
                    return browse.Result.makeRetainedError(.unknown_error) catch null;
                };
                load_entry.value_ptr.* = .{};
                defer _ = self.internal.load_listeners.remove(load_req_id);

                ws.writeBin(load_req_msg) catch |err| {
                    std.log.err("Unable to write load request: {s}", .{@errorName(err)});
                    return browse.Result.makeRetainedError(.failed_to_send) catch null;
                };

                std.log.debug("Sent load request (ID={d})", .{load_req_id});

                const load_resp = load_entry.value_ptr.listen() catch {
                    std.log.err("Load request timeout", .{});
                    return browse.Result.makeRetainedError(.timeout) catch null;
                };
                defer load_resp.deinit();

                const action = browse.ListAction.make(load_resp.value) catch {
                    return browse.Result.makeRetainedError(.out_of_memory) catch null;
                };
                return browse.Result.makeRetained(.{ .list = action }) catch null;
            },
            .none => {
                return browse.Result.makeRetained(.none) catch null;
            },
        }
    }

    pub fn getImage(
        ptr: ?*Connection,
        image_key_ptr: [*:0]const u8,
        opts_ptr: ?*image.GetOptions,
    ) callconv(.C) ?*image.GetResult {
        var self = ptr orelse @panic(
            std.fmt.comptimePrint("Received null pointer on {s}_{s}", .{ cname, @src().fn_name }),
        );

        const image_key = std.mem.span(image_key_ptr);

        const req = req: {
            const opts = image.GetOptions.retain(opts_ptr);
            defer opts.release();

            var r = ImageService.Get.Request{
                .image_key = image_key,
                .format = if (opts.internal.data.content_type) |t| switch (t) {
                    .jpeg => .jpeg,
                    .png => .png,
                } else null,
            };

            if (opts.internal.data.size) |size| {
                r.scale = switch (size.scaling_method) {
                    .fit => .fit,
                    .fill => .fill,
                    .stretch => .stretch,
                };
                r.width = size.width;
                r.height = size.height;
            }

            break :req r;
        };

        return self.internal.image_downloads.download(self.internal.tsa.allocator(), &req, self.internal.server) catch {
            std.log.err("Out of memory during image download", .{});
            return image.GetResult.makeRetainedError(.out_of_memory) catch null;
        };
    }

    pub fn export_capi() void {
        @export(&make, .{ .name = std.fmt.comptimePrint("{s}_make", .{cname}) });
        @export(&retain, .{ .name = std.fmt.comptimePrint("{s}_retain", .{cname}) });
        @export(&release, .{ .name = std.fmt.comptimePrint("{s}_release", .{cname}) });
        @export(&getEvent, .{ .name = std.fmt.comptimePrint("{s}_get_event", .{cname}) });
        @export(&subscribeZones, .{ .name = std.fmt.comptimePrint("{s}_subscribe_zones", .{cname}) });
        @export(&control, .{ .name = std.fmt.comptimePrint("{s}_control", .{cname}) });
        @export(&seek, .{ .name = std.fmt.comptimePrint("{s}_seek", .{cname}) });
        @export(&increaseVolume, .{ .name = std.fmt.comptimePrint("{s}_increase_volume", .{cname}) });
        @export(&decreaseVolume, .{ .name = std.fmt.comptimePrint("{s}_decrease_volume", .{cname}) });
        @export(&changeVolume, .{ .name = std.fmt.comptimePrint("{s}_change_volume", .{cname}) });
        @export(&requestBrowse, .{ .name = std.fmt.comptimePrint("{s}_browse", .{cname}) });
        @export(&getImage, .{ .name = std.fmt.comptimePrint("{s}_get_image", .{cname}) });
    }
};

pub fn export_capi() void {
    ConnectionErrorEvent.export_capi();
    ConnectedEvent.export_capi();
    Event.export_capi();
    Connection.export_capi();
}