1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace Plac {
namespace Discovery {
public async Plac.Discovery.ScanResult? scan_async() {
	GLib.SourceFunc callback = scan_async.callback;
	Plac.Discovery.ScanResult? result = null;

	new GLib.Thread<void>("server-scanner", () => {
				result = Plac.Discovery.scan();
				GLib.Idle.add((owned) callback);
			});

	yield;
	return (owned) result;
}
}

public class AsyncConnection : GLib.Object {
	private Connection conn;
	private GLib.Thread<void>? thread;
	private bool is_closed;

	public AsyncConnection(Discovery.Server server) {
		this.conn = new Connection(server, null);
		this.thread = null;
		this.is_closed = false;
	}

	public signal void connection_started();
	public signal void out_of_memory_error();
	public signal void connection_error(ConnectionErrorEvent event);
	public signal void connected(ConnectedEvent event);
	public signal void zones_changed(Transport.ZoneListEvent event);

	public void activate() {
		if (thread != null) {
			return;
		}

		is_closed = false;

		thread = new GLib.Thread<void>("connection-loop", () => {
				GLib.Idle.add(() => {
					connection_started();
					return false;
				});

				while (true) {
					if (is_closed) {
						return;
					}

					var event = conn.get_event();

					if (event == null) {
						deactivate();
						GLib.Idle.add(() => {
							out_of_memory_error();
							return false;
						});
						return;
					}

					switch (event.kind) {
						case ERROR: {
							deactivate();
							GLib.Idle.add(() => {
								connection_error(event.get_connection_error_event());
								return false;
							});
							break;
						}
						case CONNECTED: {
							conn.subscribe_zones();
							GLib.Idle.add(() => {
								connected(event.get_connected_event());
								return false;
							});
							break;
						}
						case ZONE_LIST: {
							GLib.Idle.add(() => {
								zones_changed(event.get_zone_list_event());
								return false;
							});
							break;
						}
					}
				}
			});
	}

	public void deactivate() {
		if (thread == null) {
			return;
		}

		// Prevent unnecessary read immediately.
		is_closed = true;

		// Schedule thread disposal. Calling `thread.join` immediately results in
		// `join` from the same thread = deadlock.
		GLib.Idle.add(() => {
				thread.join();
				return false;
			});
	}
}
}