/gtk-adwaita/src/Widgets/ZoneOutputRow.vala at a44d94419afc5f27ff5034674a806494477bbef6

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
[GtkTemplate(ui = "/jp/pocka/plac/gtk-adwaita/ui/zone-output-row.ui")]
class ZoneOutputRow : Gtk.ListBoxRow {
	[GtkChild]
	private unowned Gtk.Label display_name;

	[GtkChild]
	private unowned Gtk.Box incremental_control;

	[GtkChild]
	private unowned Gtk.Box value_control;

	[GtkChild]
	private unowned Gtk.Scale volume_slider;

	[GtkChild]
	private unowned Gtk.Button volume_up_incr;

	[GtkChild]
	private unowned Gtk.Button volume_up;

	[GtkChild]
	private unowned Gtk.Button volume_down_incr;

	[GtkChild]
	private unowned Gtk.Button volume_down;

	public bool stale = false;

	public string output_id {
		get { return _output.id; }
	}

	public Plac.AsyncConnection? conn { get; set construct; }

	private Plac.Transport.Output _output;
	public Plac.Transport.Output output {
		get { return _output; }
		set construct {
			_output = value;
			display_name.label = value.display_name;
			if (value.is_incremental_volume) {
				incremental_control.visible = true;
				value_control.visible = false;
			} else {
				incremental_control.visible = false;
				value_control.visible = true;
				if (volume_slider.adjustment.lower != output.volume.min) {
					volume_slider.adjustment.lower = output.volume.min;
				}
				if (volume_slider.adjustment.upper != output.volume.max) {
					volume_slider.adjustment.upper = output.volume.max;
				}
				if (!is_moving_volume && volume_slider.adjustment.value != output.volume.value) {
					volume_slider.adjustment.value = output.volume.value;
				}
				if (volume_slider.adjustment.step_increment != output.volume.step) {
					volume_slider.adjustment.step_increment = output.volume.step;
				}
			}
		}
	}

	private bool is_incrementing_volume = false;

	// true = increase, false = decrease
	private Gee.ArrayQueue<bool>volume_increment_queue = new Gee.ArrayQueue<bool>();

	private bool is_moving_volume = false;
	private double? next_volume_move_to = null;

	public ZoneOutputRow(Plac.Transport.Output output) {
		Object(output: output);
	}

	construct {
		volume_up_incr.clicked.connect(() => {
				queue_incremental_volume_change(true);
			});

		volume_up.clicked.connect(() => {
				var current = next_volume_move_to != null ? next_volume_move_to : output.volume.value;
				schedule_volume_change(current + output.volume.step);
			});

		volume_down_incr.clicked.connect(() => {
				queue_incremental_volume_change(false);
			});

		volume_down.clicked.connect(() => {
				var current = next_volume_move_to != null ? next_volume_move_to : output.volume.value;
				schedule_volume_change(current - output.volume.step);
			});

		volume_slider.change_value.connect((scroll, value) => {
				schedule_volume_change(value);
				return false;
			});
	}

	private void queue_incremental_volume_change(bool is_increase) {
		volume_increment_queue.offer(is_increase);

		if (!is_incrementing_volume) {
			is_incrementing_volume = true;
			dequeue_incremental_volume_change();
		}
	}

	private void dequeue_incremental_volume_change() {
		if (conn == null || volume_increment_queue.is_empty) {
			is_incrementing_volume = false;
			return;
		}

		var next = volume_increment_queue.poll();

		if (next) {
			conn.increase_volume.begin(output, (obj, res) => {
					var code = conn.increase_volume.end(res);
					if (code != OK) {
						GLib.log("Plac", LEVEL_WARNING, "Increase volume failed: %s", code.to_string());
					}

					dequeue_incremental_volume_change();
				});
		} else {
			conn.decrease_volume.begin(output, (obj, res) => {
					var code = conn.decrease_volume.end(res);
					if (code != OK) {
						GLib.log("Plac", LEVEL_WARNING, "Decrease volume failed: %s", code.to_string());
					}

					dequeue_incremental_volume_change();
				});
		}
	}

	private void schedule_volume_change(double value) {
		next_volume_move_to = value;

		if (!is_moving_volume) {
			is_moving_volume = true;
			take_volume_change();
		}
	}

	private void take_volume_change() {
		if (conn == null || next_volume_move_to == null) {
			is_moving_volume = false;
			return;
		}

		var value = next_volume_move_to;
		next_volume_move_to = null;

		conn.change_volume.begin(output, value, (obj, res) => {
				var code = conn.change_volume.end(res);
				if (code != OK) {
					GLib.log("Plac", LEVEL_WARNING, "Change volume failed: %s", code.to_string());
				}

				take_volume_change();
			});
	}
}
}