1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace Plac {
	public errordomain RequestError {
		NETWORK_ERROR,
		UNEXPECTED_RESPONSE,
	}

	// TODO: Handle connection close and reconnect
	public class Connection : Object {
		private size_t request_id = 1;

		public Soup.WebsocketConnection conn { get; construct; }
		public Server server { get; construct; }
		public string token { get; construct; }

		public Connection(Soup.WebsocketConnection conn, Server server, string token) {
			Object(conn: conn, server: server, token: token);
		}

		construct {
			// Roon forces application-layer ping/pong instead of WebSocket's
			// ping/pong frame.
			conn.message.connect((c, type, bytes) => {
				var message = (string) bytes.get_data();

				Moo.Metadata req_meta;
				Moo.Headers req_headers;
				try {
					req_meta = new Moo.Metadata.from_string(message);
					req_headers = new Moo.Headers.from_string(message, req_meta);
				} catch (GLib.Error error) {
					GLib.log("Plac", LEVEL_WARNING, "Got invalid MOO message: %s", error.message);
					return;
				}

				if (req_meta.service != "com.roonlabs.ping:1/ping") {
					return;
				}

				var res_meta = new Moo.Metadata("COMPLETE", "Success");
				var res_headers = new Moo.Headers();
				res_headers.write("Request-Id", @"$(req_headers.request_id)");

				conn.send_binary(@"$res_meta$res_headers".data);
			});
		}

		public async Response json_request(string service, string body) throws RequestError {
			SourceFunc callback = json_request.callback;

			var req_id = request_id;
			request_id += 1;

			Response? resp = null;
			GLib.Error? error = null;

			var message_handler_id = conn.message.connect((c, type, bytes) => {
				var message = (string) bytes.get_data();

				Moo.Metadata res_meta;
				Moo.Headers res_headers;
				try {
					res_meta = new Moo.Metadata.from_string(message);
					res_headers = new Moo.Headers.from_string(message, res_meta);
				} catch (GLib.Error error) {
					GLib.log("Plac", LEVEL_WARNING, "Got invalid MOO message: %s", error.message);
					return;
				}

				if (res_meta.verb == "REQUEST" || res_headers.request_id != req_id) {
					return;
				}

				resp = new Response(res_meta, res_headers, message);
				callback();
			});

			var error_handler_id = conn.error.connect((c, error) => {
				GLib.log("Plac", LEVEL_ERROR, "Failed to receive MOO message: %s", error.message);
				callback();
			});

			var req_meta = new Moo.Metadata("REQUEST", service);
			var req_headers = new Moo.Headers();
			req_headers.write("Request-Id", @"$req_id");

			req_headers.write("Content-Type", "application/json");
			req_headers.write("Content-Length", @"$(body.length)");

			conn.send_binary(@"$req_meta$req_headers$body".data);

			yield;

			conn.disconnect(message_handler_id);
			conn.disconnect(error_handler_id);

			if (error != null) {
				throw new RequestError.NETWORK_ERROR(error.message);
			}

			if (resp == null) {
				throw new RequestError.UNEXPECTED_RESPONSE("Got unexpected response from Roon server, failed to parse.");
			}

			return resp;
		}
	}
}