1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace Plac {
	namespace V2 {
		public errordomain ResolveServerError {
			SERVER_NOT_FOUND,
			SERVER_MISMATCH,
			NETWORK_ERROR,
		}

		public class Server : Object {
			/**
			 * IP address of the server.
			 */
			public GLib.InetSocketAddress address { get; construct; }

			/**
			 * TCP port for WebSocket and HTTP connection.
			 */
			public uint16 http_port { get; construct; }

			/**
			 * String uniquely identifies a server among servers in a network.
			 */
			public string id { get; construct; }

			public string version { get; construct; }

			/**
			 * User-facing display name.
			 */
			public string name { get; construct; }

			public Server(GLib.InetSocketAddress address, string id, string version, string name, uint16 http_port) {
				Object(address: address, id: id, version: version, name: name, http_port: http_port);
			}

			public static async Server from_address(
				GLib.InetSocketAddress address, uint16 http_port, string id, GLib.Cancellable? cancellable = null
			) throws ResolveServerError {
				var session_singleton = new Session();
				var session = session_singleton.session;

				var url = GLib.Uri.build(
					NONE, "ws:", null, address.address.to_string(), http_port,
					"/api", null, null
				);
				var msg = new Soup.Message.from_uri("GET", url);

				Soup.WebsocketConnection conn;
				try {
					// Roon API does not specify WebSocket subprotocols.
					conn = yield session.websocket_connect_async(
						msg, null, null, GLib.Priority.DEFAULT, cancellable
					);
				} catch (GLib.Error error) {
					GLib.log("Plac", LEVEL_DEBUG, "Handshake error");
					throw new ResolveServerError.NETWORK_ERROR(error.message);
				}

				var message = yield get_message(conn);

				Moo.Metadata meta;
				Moo.Headers headers;
				Roon.Registry.Info.Response info;
				try {
					meta = new Moo.Metadata.from_string(message);
					headers = new Moo.Headers.from_string(message, meta);
					if (headers.request_id != 1) {
						throw new ResolveServerError.SERVER_MISMATCH("Request-Id does not match.");
					}
					if (headers.content_type != "application/json") {
						throw new ResolveServerError.SERVER_MISMATCH("Not a JSON body.");
					}
					var body = new Moo.JsonBody.from_string(message, headers);
					info = new Roon.Registry.Info.Response.from_json(body.data);
				} catch (GLib.Error error) {
					throw new ResolveServerError.SERVER_MISMATCH(error.message);
				}

				if (info == null) {
					throw new ResolveServerError.SERVER_MISMATCH("Got invalid info response");
				}

				if (info.core_id != id) {
					throw new ResolveServerError.SERVER_MISMATCH("Server at the location has different server ID.");
				}

				return new Server(address, id, info.display_version, info.display_name, http_port);
			}

			private static async string get_message(Soup.WebsocketConnection conn) throws ResolveServerError {
				SourceFunc callback = get_message.callback;
				GLib.Bytes? bytes = null;

				conn.message.connect((c, type, b) => {
					bytes = b;
					callback();
				});

				conn.error.connect((c, error) => {
					callback();
				});

				conn.send_binary(build_request().data);

				yield;

				if (bytes == null) {
					throw new ResolveServerError.SERVER_NOT_FOUND("Server not found.");
				}

				return (string) GLib.Bytes.unref_to_data(bytes);
			}

			private static string build_request() {
				var meta = new Moo.Metadata("REQUEST", "com.roonlabs.registry:1/info");

				var headers = new Moo.Headers();
				headers.write("Request-Id", "1");

				return @"$meta$headers";
			}
		}
	}
}