1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

using GLib;

namespace Roon {
	/**
	 * json-glib has unbelievably loose value getters.
	 * This namespace provides sane getters wrapping original ones.
	 * Setters in this class throws an error instead of incorrectly cast values.
	 */
	namespace JsonHelper {
		public errordomain ParseError {
			UNEXPECTED_TYPE,
		}

		internal class FieldPath {
			public FieldPath? parent;
			public string path;

			public FieldPath(string path, FieldPath? parent = null) {
				this.path = path;
				this.parent = parent;
			}

			public string to_string() {
				return (parent != null) ? @"$(parent).$(path)" : path;
			}

			public string to_prefix() {
				if (this == null) {
					return "";
				}

				return @"$(this): ";
			}
		}

		internal static Json.Node get_member(Json.Object obj, FieldPath? path) throws ParseError {
			var node = obj.get_member(path.path);
			if (node == null) {
				throw new ParseError.UNEXPECTED_TYPE(@"$(path.to_prefix())Expected \"$(path.path)\" field, but the field is missing or null.");
			}
			return node;
		}

		internal static Json.Node? get_optional_member(Json.Object obj, FieldPath? path) {
			var node = obj.get_member(path.path);

			if (node == null || node.is_null()) {
				return null;
			}

			return node;
		}

		internal static string get_string(Json.Node node, FieldPath? path) throws ParseError {
			var str = node.get_string();
			if (str == null) {
				throw new ParseError.UNEXPECTED_TYPE(@"$(path.to_prefix())Expected String, got $(node.get_value_type().to_string()).");
			}

			return str;
		}

		internal static bool get_boolean(Json.Node node, FieldPath? path) throws ParseError {
			var type = node.get_value_type();
			if (type != Type.BOOLEAN) {
				throw new ParseError.UNEXPECTED_TYPE(@"$(path.to_prefix())Expected Boolean, got $(type.to_string()).");
			}

			return node.get_boolean();
		}

		internal static int64 get_int(Json.Node node, FieldPath? path) throws ParseError {
			var type = node.get_value_type();
			if (type != Type.INT64) {
				throw new ParseError.UNEXPECTED_TYPE(@"$(path.to_prefix())Expected Int, got $(type.to_string())");
			}

			return node.get_int();
		}

		internal static double get_double(Json.Node node, FieldPath? path) throws ParseError {
			var type = node.get_value_type();

			switch (type) {
			case Type.DOUBLE:
				return node.get_double();
			// JavaScript does not distinct integer and float. We can't assume float field does not
			// contain integer.
			case Type.INT64:
				return (double) node.get_int();
				default:
				throw new ParseError.UNEXPECTED_TYPE(@"$(path.to_prefix())Expected Double, got $(type.to_string())");
			}
		}

		internal static Json.Object get_object(Json.Node node, FieldPath? path) throws ParseError {
			var type = node.get_node_type();
			if (type != Json.NodeType.OBJECT) {
				throw new ParseError.UNEXPECTED_TYPE(@"$(path.to_prefix())Expected Object, got $(type.to_string())");
			}

			return (!) node.get_object();
		}

		internal static Json.Array get_array(Json.Node node, FieldPath? path) throws ParseError {
			var type = node.get_node_type();
			if (type != Json.NodeType.ARRAY) {
				throw new ParseError.UNEXPECTED_TYPE(@"$(path.to_prefix())Expected Array, got $(type.to_string())");
			}

			return (!) node.get_array();
		}
	}
}