/gtk-adwaita/src/Widgets/PlaybackToolbar.vala at 7612e6b02ccdd646835669ac2701ea1376ffc564

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
[GtkTemplate(ui = "/jp/pocka/plac/gtk-adwaita/ui/playback-toolbar.ui")]
class PlaybackToolbar : Gtk.Box {
	public signal void zone_selected(Plac.Transport.Zone? zone);

	[GtkChild]
	private unowned Gtk.Button play;

	[GtkChild]
	private unowned Gtk.Button pause;

	[GtkChild]
	private unowned Gtk.Button prev;

	[GtkChild]
	private unowned Gtk.Button next;

	[GtkChild]
	private unowned Gtk.Scale seek;

	[GtkChild]
	private unowned Gtk.Label playing_line1;

	[GtkChild]
	private unowned Gtk.Label playing_line2;

	[GtkChild]
	private unowned Gtk.Popover zone_list_popover;

	[GtkChild]
	private unowned Gtk.ListBox zone_list;

	private Gee.HashMap<string, ZoneSelectorRow>zone_rows = new Gee.HashMap<string, ZoneSelectorRow>();

	private string? zone_id = null;

	private Plac.Transport.Zone? zone {
		get {
			var row = zone_rows[zone_id];
			if (row == null) {
				return null;
			}
			return row.zone;
		}

		set {
			if (value == null) {
				zone_id = null;
			} else {
				zone_id = value.id;
			}

			zone_selected(value);
		}
	}

	public PlaybackToolbar() {
		Object();
	}

	construct {
		zone_list.row_activated.connect((row) => {
				this.zone = ((ZoneSelectorRow) row).zone;
				zone_list_popover.popdown();
				this.render();
			});

		this.render();
	}

	public void listen(Plac.AsyncConnection conn) {
		play.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (row == null) {
					return;
				}

				conn.control(row.zone, Plac.Transport.ACTION_PLAY);
			});

		pause.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (row == null) {
					return;
				}

				conn.control(row.zone, Plac.Transport.ACTION_PAUSE);
			});

		prev.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (row == null) {
					return;
				}

				conn.control(row.zone, Plac.Transport.ACTION_PREV);
			});

		next.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (row == null) {
					return;
				}

				conn.control(row.zone, Plac.Transport.ACTION_NEXT);
			});

		conn.zones_changed.connect((event) => {
				foreach (string id in event.removed) {
					GLib.log("Plac", LEVEL_DEBUG, "Zone id=%s removed", id);

					if (zone_rows.has_key(id)) {
						var existing = zone_rows[id];
						zone_rows.unset(id);
						zone_list.remove(existing);
					}
				}

				foreach (Plac.Transport.Zone zone in event.added) {
					GLib.log("Plac", LEVEL_DEBUG, "Zone (%s) id=%s added", zone.name, zone.id);
					if (zone_rows.has_key(zone.id)) {
						var existing = zone_rows[zone.id];
						existing.zone = zone;
						existing.render();
					} else {
						var row = new ZoneSelectorRow(zone);
						zone_rows[zone.id] = row;
						zone_list.append(row);

						if (zone_id == null) {
							this.zone = zone;
						}
					}
				}

				foreach (Plac.Transport.Zone zone in event.changed) {
					GLib.log("Plac", LEVEL_DEBUG, "Zone (%s) id=%s changed", zone.name, zone.id);
					if (zone_rows.has_key(zone.id)) {
						var existing = zone_rows[zone.id];
						existing.zone = zone;
						existing.render();
					} else {
						var row = new ZoneSelectorRow(zone);
						zone_rows[zone.id] = row;
						zone_list.append(row);

						if (zone_id == null) {
							this.zone = zone;
						}
					}
				}

				foreach (Plac.Transport.SeekChange change in event.seek_changed) {
					if (zone_rows.has_key(change.zone_id)) {
						var zone = zone_rows[change.zone_id].zone;
						if (zone.now_playing != null) {
							zone.now_playing.seek_position = change.seek_position;
							zone.now_playing.has_seek_position = true;
						}
					}
				}

				// Selected zone has been removed.
				if (zone_id != null && !zone_rows.has_key(zone_id)) {
					this.zone = null;

					foreach (var entry in zone_rows) {
						this.zone = entry.value.zone;
						break;
					}
				}

				this.render();
			});
	}

	private void render() {
		var zone = this.zone;
		if (zone == null) {
			play.visible = true;
			pause.visible = false;
			return;
		}

		play.sensitive = (zone.allowed_action & Plac.Transport.ACTION_PLAY) != 0;
		pause.sensitive = (zone.allowed_action & Plac.Transport.ACTION_PAUSE) != 0;
		prev.sensitive = (zone.allowed_action & Plac.Transport.ACTION_PREV) != 0;
		next.sensitive = (zone.allowed_action & Plac.Transport.ACTION_NEXT) != 0;

		if (zone.now_playing != null) {
			playing_line1.label = zone.now_playing.two_line_line1;
			playing_line2.label = zone.now_playing.two_line_line2 != null
			        ? zone.now_playing.two_line_line2
			        : "";
		} else {
			playing_line1.label = "";
			playing_line2.label = "";
		}

		if (
			zone.now_playing != null &&
			zone.now_playing.has_length &&
			zone.now_playing.has_seek_position
		) {
			seek.sensitive = true;
			seek.set_range(0, zone.now_playing.length);
			seek.set_value(zone.now_playing.seek_position);
		} else {
			seek.sensitive = false;
			seek.set_range(0, 1);
			seek.set_value(0);
		}

		switch (zone.playback) {
		case LOADING:
		case STOPPED:
		case PAUSED:
			play.visible = true;
			pause.visible = false;
			break;
		case PLAYING:
			play.visible = false;
			pause.visible = true;
			break;
		}
	}
}

class ZoneSelectorRow : Gtk.ListBoxRow {
	private Gtk.Label label;

	public Plac.Transport.Zone zone { get; construct set; }

	public ZoneSelectorRow(Plac.Transport.Zone zone) {
		Object(zone: zone);
	}

	construct {
		label = new Gtk.Label(zone.name);
		this.child = label;
		this.activatable = true;
	}

	public void render() {
		this.label.label = zone.name;
	}
}
}