1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144
145. 145
146. 146
147. 147
148. 148
149. 149
150. 150
151. 151
152. 152
153. 153
154. 154
155. 155
156. 156
157. 157
158. 158
159. 159
160. 160
161. 161
162. 162
163. 163
164. 164
165. 165
166. 166
167. 167

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

const std = @import("std");

const ApiSpec = @import("./ApiSpec.zig");

fn writeBaseType(writer: anytype, t: ApiSpec.CBaseType) !void {
    switch (t) {
        .bool, .char, .void => try writer.writeAll(@tagName(t)),
        .custom => |name| try writer.writeAll(name),
        .int, .uint => |bits| {
            try std.fmt.format(writer, "{s}{d}_t", .{
                if (t == .int) "int" else "uint",
                bits,
            });
        },
    }
}

fn writeType(writer: anytype, t: ApiSpec.CType) !void {
    switch (t) {
        .pointer => |pointer| {
            if (pointer.@"const") {
                try writer.writeAll("const ");
            }

            try writeBaseType(writer, pointer.type);
            try writer.writeAll(" *");
        },
        .value => |child| try writeBaseType(writer, child),
    }
}

fn writeFunction(writer: anytype, cname: []const u8, f: ApiSpec.Function) !void {
    try writeType(writer, f.return_type);
    try std.fmt.format(writer, " {s}_{s}(", .{ cname, f.name });

    for (f.parameters, 0..) |param, i| {
        if (i > 0) {
            try writer.writeAll(", ");
        }

        try writeType(writer, param.type);
    }
    try writer.writeAll(");\n");
}

pub fn main() !void {
    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
    defer arena.deinit();

    const allocator = arena.allocator();

    var args = std.process.ArgIterator.init();
    defer args.deinit();

    _ = args.skip();

    const input = args.next() orelse {
        return error.NoInputFile;
    };

    const output = args.next() orelse {
        return error.NoOutputFile;
    };

    if (args.next()) |_| {
        return error.TooManyArgument;
    }

    const input_file = try std.fs.cwd().openFile(input, .{});
    defer input_file.close();

    var source = std.json.reader(allocator, input_file.reader());

    const parsed = try std.json.parseFromTokenSource(ApiSpec, allocator, &source, .{});
    defer parsed.deinit();

    const spec = parsed.value;

    const output_file = try std.fs.cwd().createFile(output, .{});
    defer output_file.close();

    const writer = output_file.writer();

    try writer.writeAll(
        \\#ifndef ROON_MSG_H
        \\#define ROON_MSG_H
        \\
        \\#include <stdbool.h>
        \\#include <stddef.h>
        \\#include <stdint.h>
        \\
        \\
    );

    for (spec.items) |item| {
        switch (item) {
            .@"enum" => |info| {
                try writer.writeAll("typedef enum {\n");

                const ns = try std.ascii.allocUpperString(allocator, info.cname);

                for (info.fields) |field| {
                    try std.fmt.format(writer, "\t{s}_{s} = {d},\n", .{
                        ns, try std.ascii.allocUpperString(allocator, field.name), field.value,
                    });
                }

                try std.fmt.format(writer, "}} {s};\n\n", .{info.cname});
            },
            .@"opaque" => |info| {
                try std.fmt.format(writer, "typedef void {s};\n", .{info.cname});

                try writeFunction(writer, info.cname, info.new_function);

                for (info.member_functions) |member_fn| {
                    try writeFunction(writer, info.cname, member_fn);
                }

                try writer.writeByte('\n');
            },
            .@"struct" => |info| {
                try writer.writeAll("typedef struct {\n");
                // Zig has compiler bug that prevents using tab inside multiline string.
                try writer.writeAll("\tsize_t __rc;\n");

                for (info.fields) |field| {
                    try writer.writeByte('\t');
                    try writeType(writer, field.type);
                    if (field.type == .pointer and std.mem.endsWith(u8, field.name, "_ptr")) {
                        try writer.writeByte('*');
                    }
                    try writer.writeByte(' ');
                    try std.fmt.format(writer, "{s};\n", .{field.name});
                }
                try std.fmt.format(writer, "}} {s};\n", .{info.cname});

                if (info.new_function) |f| {
                    try writeFunction(writer, info.cname, f);
                }

                for (info.member_functions) |f| {
                    try writeFunction(writer, info.cname, f);
                }

                try writer.writeByte('\n');
            },
        }
    }

    try writer.writeAll("#endif\n");
}