1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144
145. 145
146. 146
147. 147
148. 148
149. 149
150. 150
151. 151
152. 152
153. 153
154. 154
155. 155
156. 156
157. 157
158. 158
159. 159
160. 160
161. 161
162. 162
163. 163

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
private errordomain ResolveError {
	CONNECTION_ERROR,
	SERVER_NOT_FOUND
}

[GtkTemplate(ui = "/jp/pocka/plac/gtk-adwaita/ui/main-window.ui")]
class MainWindow : Adw.ApplicationWindow {
	[GtkChild]
	private unowned Gtk.Label test_label;

	[GtkChild]
	private unowned Gtk.Stack root_stack;

	[GtkChild]
	private unowned PlaybackToolbar playback_toolbar;

	[GtkChild]
	private unowned Adw.Banner error_banner;

	private Settings settings = new Settings();

	private Plac.Discovery.Server? server = null;
	private Plac.AsyncConnection? conn = null;

	private string server_id;

	public MainWindow(Gtk.Application app, Plac.Discovery.Server server) {
		(typeof (ServerConnecting)).ensure();
		(typeof (PlaybackToolbar)).ensure();

		Object(application: app);
		this.server = server;
		this.conn = new Plac.AsyncConnection(server);
		this.server_id = server.id;
	}

	public MainWindow.from_server_id(Gtk.Application app, string server_id) {
		(typeof (ServerConnecting)).ensure();
		(typeof (PlaybackToolbar)).ensure();

		Object(application: app);
		this.server_id = server_id;
	}

	construct {
		error_banner.button_clicked.connect(() => {
				try_listen();
			});
	}

	public void start() {
		root_stack.visible_child_name = "loading";

		try_listen();

		this.present();
	}

	private void try_listen() {
		error_banner.revealed = false;

		if (conn != null) {
			listen_events();
		} else {
			resolve_server.begin((obj, res) => {
					try {
						resolve_server.end(res);
					} catch (ResolveError e) {
						error_banner.title = e.message;
						error_banner.revealed = true;
						return;
					}

					listen_events();
				});
		}
	}

	private void listen_events() {
		this.title = "Plac - %s".printf(server.name);
		test_label.label = server.name;

		conn.connection_started.connect(() => {
				root_stack.visible_child_name = "loading";
				playback_toolbar.visible = false;
			});

		conn.connected.connect((event) => {
				root_stack.visible_child_name = "main";
				playback_toolbar.visible = true;

				settings.connected_server_id = server_id;
				settings.connected_server_token = event.token;
			});

		conn.connection_error.connect((event) => {
				GLib.log("Plac", LEVEL_CRITICAL, "Failed to connect: %s", event.code.to_string());
				error_banner.title = "Connection error: %s".printf(event.code.to_string());
				error_banner.revealed = true;
			});

		conn.out_of_memory_error.connect(() => {
				GLib.log("Plac", LEVEL_CRITICAL, "Failed to connect: out of memory");
				error_banner.title = "Connection error (out of memory)";
				error_banner.revealed = true;
			});

		playback_toolbar.listen(conn);

		conn.activate();
	}

	private async void resolve_server() throws ResolveError {
		GLib.SourceFunc callback = resolve_server.callback;
		ResolveError? error = null;

		Plac.Discovery.find_async.begin(server_id, (obj, res) => {
				var result = Plac.Discovery.find_async.end(res);

				if (result.code != OK) {
					GLib.log("Plac", LEVEL_CRITICAL, "Failed to find server: %s", result.code.to_string());
					Idle.add((owned) callback);
					error = new ResolveError.CONNECTION_ERROR("Failed to connect: %s".printf(result.code.to_string()));
					return;
				}

				if (result.servers.length < 1) {
					GLib.log("Plac", LEVEL_CRITICAL, "Server not found: ID=%s", server_id);
					Idle.add((owned) callback);
					error = new ResolveError.SERVER_NOT_FOUND("Server not found");
					return;
				}

				server = result.servers[0];
				conn = new Plac.AsyncConnection.with_token(server, settings.connected_server_token);
				Idle.add((owned) callback);
			});

		yield;

		if (error != null) {
			throw error;
		}
	}
}
}