1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

const std = @import("std");

pub fn ObjectPool(comptime T: type, comptime size: usize) type {
    const Availability = u32;
    if (size > @bitSizeOf(Availability)) {
        @compileError(
            std.fmt.comptimePrint(
                "ObjectPool size must be less than or equals to {d} (got {d})",
                .{ @bitSizeOf(Availability), size },
            ),
        );
    }

    return struct {
        // a bit is set (1) = available, otherwise occupied.
        // ex) Availability = u8, size = 5
        //     0b00011111 = Fully available
        //     0b00011110 = First item is occupied, second item is available
        //     0b00000000.. = Fully occupied
        availability: Availability = std.math.maxInt(Availability),
        lock: std.Thread.Mutex = .{},
        cond: std.Thread.Condition = .{},
        size: usize = size,
        pool: [size]T = undefined,

        pub fn acquire(self: *@This()) *T {
            self.lock.lock();
            defer self.lock.unlock();

            while (true) {
                const index = @ctz(self.availability);
                if (index < size) {
                    self.availability &= ~(@as(Availability, 0b1) << @min(std.math.maxInt(u5), index));
                    return &self.pool[index];
                }

                self.cond.wait(&self.lock);
            }
        }

        pub fn release(self: *@This(), item: *const T) void {
            defer self.cond.signal();
            self.lock.lock();
            defer self.lock.unlock();

            const pool: [*]const T = &self.pool;
            self.availability |= @as(Availability, 0b1) << @min(std.math.maxInt(u5), item - pool);
        }
    };
}

test ObjectPool {
    const Pool = ObjectPool(usize, 5);

    const num_items = 6;

    const Runner = struct {
        pool: Pool = .{},
        threads: [num_items]std.Thread = undefined,
        asserted: std.Thread.ResetEvent = .{},

        wrote_lock: std.Thread.Mutex = .{},
        wrote_times: usize = 0,

        pool_exhausted: std.Thread.ResetEvent = .{},

        pub fn run(self: *@This(), i: usize) void {
            const item = self.pool.acquire();
            defer self.pool.release(item);
            item.* = i;

            {
                self.wrote_lock.lock();
                defer self.wrote_lock.unlock();

                self.wrote_times += 1;
                if (self.wrote_times == 5) {
                    self.pool_exhausted.set();
                }
            }

            self.asserted.wait();
        }
    };

    var runner: Runner = .{};
    for (&runner.threads, 1..) |*thread, i| {
        thread.* = try std.Thread.spawn(.{}, Runner.run, .{ &runner, i });
    }
    errdefer for (runner.threads) |thread| {
        thread.detach();
    };

    try runner.pool_exhausted.timedWait(std.time.ns_per_s);
    for (runner.pool.pool) |item| {
        try std.testing.expect(item > 0);
        try std.testing.expect(item < 6);
    }

    runner.asserted.set();

    for (runner.threads) |thread| {
        thread.join();
    }

    try std.testing.expectEqual(num_items, runner.wrote_times);
}