/gtk-adwaita/src/Widgets/PlaybackToolbar.vala at e0f94d58385727f4a8dfc3a6093f89eb92dfead2

// Copyright 2025 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
[GtkTemplate(ui = "/jp/pocka/plac/gtk-adwaita/ui/playback-toolbar.ui")]
class PlaybackToolbar : Gtk.Box {
	public signal void zone_selected(Plac.Transport.Zone? zone);

	[GtkChild]
	private unowned Gtk.Box controls;

	[GtkChild]
	private unowned Gtk.Button play;

	[GtkChild]
	private unowned Gtk.Button pause;

	[GtkChild]
	private unowned Gtk.Button prev;

	[GtkChild]
	private unowned Gtk.Button next;

	[GtkChild]
	private unowned Gtk.Button seek_backwards_10;

	[GtkChild]
	private unowned Gtk.Button seek_forward_10;

	[GtkChild]
	private unowned Gtk.Scale seek;

	[GtkChild]
	private unowned Gtk.Label playing_line1;

	[GtkChild]
	private unowned Gtk.Label playing_line2;

	[GtkChild]
	private unowned Gtk.Popover zone_list_popover;

	[GtkChild]
	private unowned Gtk.ListBox zone_list;

	[GtkChild]
	private unowned Artwork artwork;

	private Gee.HashMap<string, ZoneSelectorRow>zone_rows = new Gee.HashMap<string, ZoneSelectorRow>();

	private bool is_seeking = false;
	private int64? next_seek = null;

	private string? zone_id = null;

	private Settings settings = new Settings();

	private Plac.Transport.Zone? zone {
		get {
			var row = zone_rows[zone_id];
			if (row == null) {
				return null;
			}
			return row.zone;
		}

		set {
			if (value == null) {
				zone_id = null;
			} else {
				zone_id = value.id;
			}

			zone_selected(value);
			next_seek = null;
		}
	}

	public Plac.AsyncConnection? conn {
		get {
			return artwork.conn;
		}

		set {
			if (artwork.conn != null) {
				artwork.conn.zones_changed.disconnect(on_zone_change);
			}

			artwork.conn = value;
			value.zones_changed.connect(on_zone_change);
		}
	}

	private void on_zone_change(Plac.Transport.ZoneListEvent event) {
		foreach (string id in event.removed) {
			GLib.log("Plac", LEVEL_DEBUG, "Zone id=%s removed", id);

			if (zone_rows.has_key(id)) {
				var existing = zone_rows[id];
				zone_rows.unset(id);
				zone_list.remove(existing);
			}
		}

		foreach (Plac.Transport.Zone zone in event.added) {
			if (zone_rows.has_key(zone.id)) {
				var existing = zone_rows[zone.id];
				existing.zone = zone;
				existing.render();
			} else {
				var row = new ZoneSelectorRow(zone);
				zone_rows[zone.id] = row;
				zone_list.append(row);

				if (zone_id == null) {
					this.zone = zone;
				}
			}
		}

		foreach (Plac.Transport.Zone zone in event.changed) {
			if (zone_rows.has_key(zone.id)) {
				var existing = zone_rows[zone.id];
				existing.zone = zone;
				existing.render();
			} else {
				var row = new ZoneSelectorRow(zone);
				zone_rows[zone.id] = row;
				zone_list.append(row);

				if (zone_id == null) {
					this.zone = zone;
				}
			}
		}

		foreach (Plac.Transport.SeekChange change in event.seek_changed) {
			if (zone_rows.has_key(change.zone_id)) {
				var zone = zone_rows[change.zone_id].zone;
				if (zone.now_playing != null) {
					zone.now_playing.seek_position = change.seek_position;
					zone.now_playing.has_seek_position = true;
				}
			}
		}

		// Selected zone has been removed.
		if (zone_id != null && !zone_rows.has_key(zone_id)) {
			this.zone = null;

			foreach (var entry in zone_rows) {
				this.zone = entry.value.zone;
				break;
			}
		}

		this.render();
	}

	public PlaybackToolbar() {
		Object();
	}

	construct {
		zone_list.row_activated.connect((row) => {
				this.zone = ((ZoneSelectorRow) row).zone;
				zone_list_popover.popdown();
				this.render();
			});

		play.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (conn == null || row == null) {
					return;
				}

				this.disable_actions();
				conn.control.begin(row.zone, Plac.Transport.ACTION_PLAY, (obj, res) => {
					conn.control.end(res);
					this.enable_actions();
				});
			});

		pause.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (conn == null || row == null) {
					return;
				}

				this.disable_actions();
				conn.control.begin(row.zone, Plac.Transport.ACTION_PAUSE, (obj, res) => {
					conn.control.end(res);
					this.enable_actions();
				});
			});

		prev.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (conn == null || row == null) {
					return;
				}

				this.disable_actions();
				conn.control.begin(row.zone, Plac.Transport.ACTION_PREV, (obj, res) => {
					conn.control.end(res);
					this.enable_actions();
				});
			});

		next.clicked.connect(() => {
				var row = zone_rows[zone_id];
				if (conn == null || row == null) {
					return;
				}

				this.disable_actions();
				conn.control.begin(row.zone, Plac.Transport.ACTION_NEXT, (obj, res) => {
					conn.control.end(res);
					this.enable_actions();
				});
			});

		seek.change_value.connect((scroll, value) => {
				schedule_seek((int64) value);
				return false;
			});

		seek_backwards_10.clicked.connect(() => {
				var next_value = seek.get_value() - 10;
				seek.set_value(next_value);
				schedule_seek((int64) next_value);
			});

		seek_forward_10.clicked.connect(() => {
				var next_value = seek.get_value() + 10;
				seek.set_value(next_value);
				schedule_seek((int64) next_value);
			});


		seek.set_increments(1, 10);

		settings.settings.bind(Settings.SHOW_SEEK_BY_10SECS, seek_backwards_10, "visible", GET);
		settings.settings.bind(Settings.SHOW_SEEK_BY_10SECS, seek_forward_10, "visible", GET);

		this.render();
	}

	private void dequeue_seek() {
		if (conn == null || next_seek == null || zone == null) {
			is_seeking = false;
			return;
		}

		var position = next_seek;
		next_seek = null;

		conn.seek.begin(zone, position, (obj, res) => {
				var result = conn.seek.end(res);

				if (result != OK) {
					GLib.log("Plac", LEVEL_WARNING, "Failed to seek: %s", result.to_string());
				}

				dequeue_seek();
			});
	}

	private void schedule_seek(int64 position) {
		next_seek = position;

		if (!is_seeking) {
			is_seeking = true;
			dequeue_seek();
		}
	}

	private string format_seconds(uint64 secs) {
		var s = secs % 60;
		var m = (secs / 60) % 60;
		var h = secs / 360;

		if (h == 0) {
			return "%02u:%02u".printf((uint) m, (uint) s);
		}

		// I don't care 32 bit platforms. Also I doubt Roon can handle a song
		// of a duration longer than max(uint32)
		return "%02u:%02u:%02u".printf((uint) h, (uint) m, (uint) s);
	}

	private void render() {
		var zone = this.zone;
		if (zone == null) {
			play.visible = true;
			pause.visible = false;
			return;
		}

		play.sensitive = (zone.allowed_action & Plac.Transport.ACTION_PLAY) != 0;
		pause.sensitive = (zone.allowed_action & Plac.Transport.ACTION_PAUSE) != 0;
		prev.sensitive = (zone.allowed_action & Plac.Transport.ACTION_PREV) != 0;
		next.sensitive = (zone.allowed_action & Plac.Transport.ACTION_NEXT) != 0;

		if (zone.now_playing != null) {
			playing_line1.label = zone.now_playing.two_line_line1;
			playing_line2.label = zone.now_playing.two_line_line2 != null
			        ? zone.now_playing.two_line_line2
			        : "";
			artwork.image_key = zone.now_playing.image_key;
		} else {
			playing_line1.label = "";
			playing_line2.label = "";
			artwork.image_key = null;
		}

		if (
			zone.now_playing != null &&
			zone.now_playing.has_length &&
			zone.now_playing.has_seek_position
		) {
			seek.sensitive = true;
			seek.set_range(0, zone.now_playing.length);
			seek.set_value(zone.now_playing.seek_position);
			seek.tooltip_text = format_seconds(zone.now_playing.seek_position);
		} else {
			seek.sensitive = false;
			seek.set_range(0, 1);
			seek.set_value(0);
			seek.tooltip_text = "Not playing";
		}

		switch (zone.playback) {
		case LOADING:
		case STOPPED:
		case PAUSED:
			play.visible = true;
			pause.visible = false;
			break;
		case PLAYING:
			play.visible = false;
			pause.visible = true;
			break;
		}
	}

	private void disable_actions() {
		zone_list_popover.sensitive = false;
		controls.sensitive = false;
		seek.sensitive = false;
	}

	private void enable_actions() {
		zone_list_popover.sensitive = true;
		controls.sensitive = true;
		seek.sensitive = true;
	}
}

class ZoneSelectorRow : Gtk.ListBoxRow {
	private Gtk.Label label;

	public Plac.Transport.Zone zone { get; construct set; }

	public ZoneSelectorRow(Plac.Transport.Zone zone) {
		Object(zone: zone);
	}

	construct {
		label = new Gtk.Label(zone.name);
		this.child = label;
		this.activatable = true;
	}

	public void render() {
		this.label.label = zone.name;
	}
}
}