1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144
145. 145
146. 146
147. 147
148. 148
149. 149
150. 150
151. 151
152. 152
153. 153
154. 154
155. 155
156. 156
157. 157
158. 158
159. 159
160. 160
161. 161
162. 162
163. 163
164. 164
165. 165
166. 166
167. 167
168. 168
169. 169

# Copyright (C) 2025 Shota FUJI
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.
#
# SPDX-License-Identifier: GPL-3.0-only

{
  inputs = {
    nixpkgs = {
      url = "github:nixos/nixpkgs/nixpkgs-unstable";
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        nativeBuildInputs = with pkgs; [
          zig
          asciidoctor
        ];

        buildInputs = with pkgs; [
          # Database of current and historical time zones
          # http://www.iana.org/time-zones
          tzdata
        ];
      in
      {
        packages.default = pkgs.stdenvNoCC.mkDerivation {
          inherit buildInputs;

          pname = "sunwaitz";
          version = "0.91.0";
          src = pkgs.lib.sourceByRegex ./. [
            "^src.*"
            "^docs.*"
            "^dist.*"
            "build.zig"
          ];

          meta = {
            mainProgram = "sunwait";
          };

          nativeBuildInputs = nativeBuildInputs ++ [ pkgs.zig.hook ];

          zigBuildFlags = [
            "-Dman"
            "-Dzsh-completion"
            "-Dfish-completion"
          ];
        };

        apps =
          let
            sunwait = self.packages.${system}.default;
          in
          {
            # $ nix run .#zsh
            # Bare-bone Zsh session for testing completion
            zsh =
              let
                test-zsh = pkgs.symlinkJoin {
                  name = "sunwait-test-zsh";

                  nativeBuildInputs = [ pkgs.makeWrapper ];

                  paths = [
                    pkgs.zsh
                    self.packages.${system}.default
                  ];

                  postBuild = ''
                    mkdir -p $out/share/$name
                    echo 'fpath+=${sunwait}/share/zsh/site-functions' >> $out/share/$name/.zshrc
                    echo 'autoload -U compinit && compinit' >> $out/share/$name/.zshrc
                    chmod +x $out/share/$name/.zshrc

                    wrapProgram $out/bin/zsh \
                      --set ZDOTDIR $out/share/$name \
                      --set MANPATH :${sunwait}/share/man \
                      --prefix PATH : ${pkgs.lib.makeBinPath [ sunwait ]}
                  '';
                };
              in
              {
                type = "app";
                program = "${test-zsh}/bin/zsh";
              };

            # $ nix run .#fish
            # Fish session with completion configured
            fish =
              let
                test-fish = pkgs.symlinkJoin {
                  name = "sunwait-test-fish";

                  nativeBuildInputs = [ pkgs.makeWrapper ];

                  paths = [
                    pkgs.fish
                    self.packages.${system}.default
                  ];

                  postBuild = ''
                    wrapProgram $out/bin/fish \
                      --set MANPATH :${sunwait}/share/man \
                      --prefix fish_complete_path : ${sunwait}/share/fish/vendor_completions.d \
                      --prefix PATH : ${pkgs.lib.makeBinPath [ sunwait ]}
                  '';
                };
              in
              {
                type = "app";
                program = "${test-fish}/bin/fish";
              };
          };

        devShell = pkgs.mkShell {
          inherit nativeBuildInputs buildInputs;

          packages = with pkgs; [
            # Code formatter
            # https://dprint.dev/
            dprint

            # Official formatter for Nix code
            # https://hackage.haskell.org/package/nixfmt
            nixfmt-rfc-style

            # Copyright and license linter based on SPDX
            # https://github.com/fsfe/reuse-tool
            reuse

            # Open Source implementation of the Windows API on top of X, OpenGL, and Unix
            # https://www.winehq.org/
            wineWowPackages.stable

            # For text editors, optional.
            # > ZLS is a non-official implementation of the Language Server Protocol for Zig
            # https://github.com/zigtools/zls
            zls
          ];
        };
      }
    );
}