1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133

{
  description = "My system configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    home-manager,
  }: let
    # Catppuccin pallet, one of: "latte", "frappe", "macchiato", "mocha"
    catppuccinTheme = "mocha";

    # Pre-defined modules
    mods = {
      essentials = import ./essentials {
        inherit catppuccinTheme;
      };

      scm = import ./scm {
        username = "Shota FUJI";
        email = "pockawoooh@gmail.com";
        gpgKeyId = "5E5148973E291363";
      };

      wayland-de = import ./wayland-de {
        inherit catppuccinTheme;
      };

      webdev = ./webdev;
    };

    mkHomeConfiguration = {
      # Platform (e.g. x86_64-linux)
      system,
      # OS username
      username,
      # Modules to include
      modules ? [mods.essentials],
      # Timezone of the machine
      timezone ? "Asia/Tokyo",
    }: let
      isDarwin = (builtins.match ".*-darwin$" system) != null;
      homeDir =
        if isDarwin
        then "/Users"
        else "/home";
    in
      home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages.${system};

        modules =
          [
            {
              home = rec {
                inherit username;
                homeDirectory = "${homeDir}/${username}";
                stateVersion = "23.11";
                sessionVariables = {
                  TZ = timezone;
                };
              };

              # Turn off Home Manager news bs
              news.display = "silent";
            }
          ]
          ++ modules;
      };

    availableSystems = [
      "aarch64-darwin"
      "x86_64-linux"
    ];
  in {
    homeConfigurations = {
      dev-linux = mkHomeConfiguration {
        system = "x86_64-linux";
        username = "pocka";
        modules = [
          mods.essentials
          mods.scm
          mods.webdev
          mods.wayland-de
        ];
      };

      pixelbook = mkHomeConfiguration {
        system = "x86_64-linux";
        username = "pockawoooh";
        modules = [
          mods.essentials
          mods.scm
          mods.webdev
        ];
      };

      scm-server = mkHomeConfiguration {
        system = "x86_64-linux";
        username = "pocka";
        modules = [
          mods.essentials
          mods.scm
        ];
      };

      mbp-m1 = mkHomeConfiguration {
        system = "aarch64-darwin";
        username = "pocka";
        modules = [
          mods.essentials
          mods.scm
          mods.webdev
        ];
      };
    };

    formatter = builtins.listToAttrs (
      builtins.map (system: {
        name = system;
        value = nixpkgs.legacyPackages.${system}.alejandra;
      })
      availableSystems
    );
  };
}