1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132

# Copyright 2023 Shota FUJI <pockawoooh@gmail.com>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
# REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
# AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
# INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
# LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
# OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
# PERFORMANCE OF THIS SOFTWARE.
#
# SPDX-License-Identifier: 0BSD
#
# ===
# Development related configurations

{
  config,
  lib,
  pkgs,
  ...
}:
let
  cfg = config.features.dev;

  toml = pkgs.formats.toml { };

  tsVala = pkgs.fetchgit {
    url = "https://codeberg.org/pocka/tree-sitter-vala";
    rev = "093d98428caa4a6fe8b873fb508b022b33fd7f48";
    hash = "sha256-68CFO+SRkqJH8LwTbrxMbfkO2UaHtSnZhJvjKHPRs3E=";
  };

  allGrammars = (
    lib.filter (d: d.pname != "vala-grammar") pkgs.vimPlugins.nvim-treesitter.allGrammars
  );
in
{
  options = {
    features.dev = {
      enable = lib.mkEnableOption "Development";
    };
  };

  imports = [ ./lsp.nix ];

  config = {
    programs = lib.mkIf cfg.enable {
      # dev tools, env vars, task runner (asdf-plugin compatible)
      # https://github.com/jdx/mise
      mise.enable = true;

      neovim = lib.mkIf config.programs.neovim.enable {
        plugins = with pkgs.vimPlugins; [
          {
            plugin = nvim-treesitter.grammarToPlugin (
              pkgs.tree-sitter.buildGrammar {
                language = "vala";
                version = "0.1.1";
                src = tsVala;
                meta.homepage = "https://codeberg.org/pocka/tree-sitter-vala";
              }
            );
            type = "viml";

            # Either nvim, Nix, or nvim-treesitter does bad job at runtime path resolving.
            # So it includes nvim-treesitter's **hard-coded** query directory and registers
            # that directory before this custom grammar plugin. Because of this incorrect
            # runtimepath order, nvim-treesitter uses parser from the above grammar but reads
            # its forcibly included query.
            # As ~/.config/nvim is special directory and cannot "win" in load order, an
            # another directory is needed.
            config = ''
              set rtp^=~/.config/nvim-treesitter-overrides
            '';
          }
          {
            plugin = nvim-treesitter.withPlugins (_: allGrammars);

            type = "lua";

            config = ''
              require("nvim-treesitter.configs").setup {
                auto_install = false,
                highlight = {
                  enable = true,
                  additional_vim_regex_highlighting = false,
                },
              }
            '';
          }
          { plugin = vim-fugitive; }
        ];
      };
    };

    # home-manager puts global config to `.config/mise/config.toml`, which
    # mise writes to on `mise settings` command.
    xdg.configFile."mise/conf.d/immutable.toml" = lib.mkIf cfg.enable {
      source = toml.generate "mise-settings" {
        settings = {
          idiomatic_version_file_enable_tools = [
            "bazel"
            "node"
          ];
        };
      };
    };

    # Have to explicitly disable default highlight query.
    # https://github.com/nvim-treesitter/nvim-treesitter/issues/3146
    xdg.configFile."nvim-treesitter-overrides/queries/vala/highlights.scm" =
      lib.mkIf cfg.enable
        { source = tsVala + "/queries/highlights.scm"; };

    xdg.configFile."nvim-treesitter-overrides/queries/vala/locals.scm" = lib.mkIf cfg.enable {
      source = tsVala + "/queries/locals.scm";
    };

    home.packages = lib.mkIf cfg.enable [
      # a structural diff tool that understands syntax
      # https://difftastic.wilfred.me.uk/
      pkgs.difftastic

      # A tool for compliance with the REUSE Initiative recommendations
      # https://reuse.software/tutorial/
      pkgs.reuse
    ];
  };
}