1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121

// Copyright 2025 Shota FUJI <pockawoooh@gmail.com>
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

//! Over-powered theme switcher.

const std = @import("std");

const ExitCode = enum(u8) {
    ok = 0,
    generic_error = 1,
    incorrect_usage = 2,

    pub fn to_u8(self: @This()) u8 {
        return @intFromEnum(self);
    }
};

const GnomeColorScheme = enum {
    default,
    @"prefer-dark",
    @"prefer-light",

    pub fn from_variant(variant: Variant) @This() {
        return switch (variant) {
            .system => .default,
            .dark => .@"prefer-dark",
            .light => .@"prefer-light",
        };
    }
};

const Variant = enum {
    system,
    dark,
    light,

    pub fn from_string(str: []const u8) ?@This() {
        inline for (@typeInfo(Variant).@"enum".fields) |field| {
            if (std.mem.eql(u8, field.name, str)) {
                return @enumFromInt(field.value);
            }
        }

        return null;
    }
};

pub fn main() !u8 {
    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
    defer arena.deinit();

    const allocator = arena.allocator();

    var iter = try std.process.ArgIterator.initWithAllocator(allocator);
    defer iter.deinit();

    // Skip program name.
    _ = iter.next();

    const initial_arg = iter.next() orelse {
        std.log.err("Argument is required.", .{});
        return ExitCode.incorrect_usage.to_u8();
    };

    const variant: Variant = Variant.from_string(initial_arg) orelse {
        std.log.err("Unknown variant \"{s}\".", .{initial_arg});
        return ExitCode.incorrect_usage.to_u8();
    };

    if (iter.next()) |_| {
        std.log.err("Too many arguments.", .{});
        return ExitCode.incorrect_usage.to_u8();
    }

    const gnome_color_scheme = GnomeColorScheme.from_variant(variant);

    {
        const result = try std.process.Child.run(.{
            .allocator = allocator,
            .argv = &.{
                "gsettings",
                "set",
                "org.gnome.desktop.interface",
                "color-scheme",
                @tagName(gnome_color_scheme),
            },
        });
        defer allocator.free(result.stdout);
        defer allocator.free(result.stderr);

        switch (result.term) {
            .Exited => |code| {
                if (code != 0) {
                    std.log.err("gsettings command exited with non-zero code: {d}", .{code});
                    return ExitCode.generic_error.to_u8();
                }
            },
            else => {
                std.log.err("gsettings command terminated unexpectedly.", .{});
                return ExitCode.generic_error.to_u8();
            },
        }

        std.log.info("Set GNOME color scheme to {s}", .{@tagName(gnome_color_scheme)});
    }

    return ExitCode.ok.to_u8();
}