1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73

// Copyright 2025 Shota FUJI <pockawoooh@gmail.com>
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

const std = @import("std");

const Variant = @import("./variant.zig").Variant;

const gio = @cImport({
    @cInclude("gio/gio.h");
});

const gobject = @cImport({
    @cInclude("glib-object.h");
});

const GnomeColorScheme = enum(c_int) {
    default = 0,
    @"prefer-dark" = 1,
    @"prefer-light" = 2,

    pub fn from_variant(variant: Variant) @This() {
        return switch (variant) {
            .system => .default,
            .dark => .@"prefer-dark",
            .light => .@"prefer-light",
        };
    }
};

pub const ApplyError = error{
    FailedToWriteGSettings,
};

pub fn apply(variant: Variant) ApplyError!void {
    const gnome_color_scheme = GnomeColorScheme.from_variant(variant);

    const gsettings = gio.g_settings_new("org.gnome.desktop.interface");
    defer gobject.g_object_unref(gsettings);

    const gsettings_wrote = gio.g_settings_set_enum(
        gsettings,
        "color-scheme",
        @intFromEnum(gnome_color_scheme),
    );

    if (gsettings_wrote == 0) {
        std.log.warn(
            "Unable to set GNOME color scheme to {s}",
            .{@tagName(gnome_color_scheme)},
        );
        return ApplyError.FailedToWriteGSettings;
    }

    // https://docs.gtk.org/gio/class.Settings.html#delay-apply-mode
    // > ...these writes may not complete by the time that g_settings_set()
    // > returns; see g_settings_sync()).
    gio.g_settings_sync();

    std.log.info("Set GNOME color scheme to {s}", .{@tagName(gnome_color_scheme)});
}