1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130

# Copyright 2025 Shota FUJI <pockawoooh@gmail.com>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
# REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
# AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
# INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
# LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
# OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
# PERFORMANCE OF THIS SOFTWARE.
#
# SPDX-License-Identifier: 0BSD
#
# Ghostty, a cross-platform terminal emulator.
# https://ghostty.org/

{
  config,
  lib,
  pkgs,
  nix-colorizer,
  ...
}:
let
  palette = config.palette.catppuccin;
in
{
  imports = [
    ../fonts/monaspace.nix
    ../palette/catppuccin.nix
  ];

  config = {
    programs.ghostty = {
      enable = true;

      installBatSyntax = lib.mkDefault config.programs.bat.enable;
      enableBashIntegration = config.programs.bash.enable;
      enableFishIntegration = config.programs.fish.enable;
      enableZshIntegration = config.programs.zsh.enable;

      settings = {
        # Somehow Ghostty renders Monaspace in incorrect size at either of platform.
        font-size = if pkgs.stdenv.isDarwin then 13 else 10;
        font-family = "Monaspace Neon Var";
        font-style = "Medium";
        font-style-bold = "Bold";
        font-style-italic = "Medium Italic";
        font-style-bold-italic = "Bold Italic";

        # * "calt" ... Contextual Alternates
        #              This feature enables Monaspace's Texture healing.
        font-feature = [ "calt" ];

        copy-on-select = false;

        keybind =
          if pkgs.stdenv.isDarwin then
            [
              "ctrl+shift+t=new_tab"
              "ctrl+shift+n=new_split:down"
              "ctrl+shift+m=new_split:right"

              "super+shift+k=resize_split:up,20"
              "super+shift+h=resize_split:left,20"
              "super+shift+j=resize_split:down,20"
              "super+shift+l=resize_split:right,20"

              "ctrl+shift+k=goto_split:up"
              "ctrl+shift+h=goto_split:left"
              "ctrl+shift+j=goto_split:down"
              "ctrl+shift+l=goto_split:right"
            ]
          else
            [
              "ctrl+shift+t=new_window"
              "ctrl+shift+n=new_window"
              "ctrl+shift+m=new_window"
            ];

        theme = "light:catppuccin-${palette.light-flavor},dark:catppuccin-${palette.dark-flavor}";
      };

      # Both iterm2-color-schemes (Ghostty sources from) and catppuccin/ghostty
      # inverts 0/7 and 15/8 (bg and fg) to make colors "bright." This is unusable
      # as the colors' semantics no longer works. 15 can't be used for foreground,
      # so the program have to read background color. The reason 4-bit colors is
      # still used today is compatibility AND theming. Theme violates widely-used
      # context is completely useless. This code defines correct Catppuccin theme.
      themes =
        let
          stripSharp = hex: lib.strings.removePrefix "#" hex;

          lighten = hex: nix-colorizer.hex.lighten hex 0.1;

          toTheme = p: {
            palette = [
              "0=${p.surface0.hex}"
              "1=${p.red.hex}"
              "2=${p.green.hex}"
              "3=${p.yellow.hex}"
              "4=${p.blue.hex}"
              "5=${p.pink.hex}"
              "6=${p.teal.hex}"
              "7=${p.subtext0.hex}"
              "8=${p.surface2.hex}"
              "9=${lighten p.red.hex}"
              "10=${lighten p.green.hex}"
              "11=${lighten p.yellow.hex}"
              "12=${lighten p.blue.hex}"
              "13=${lighten p.pink.hex}"
              "14=${lighten p.teal.hex}"
              "15=${p.text.hex}"
            ];
            background = stripSharp p.base.hex;
            foreground = stripSharp p.text.hex;
            cursor-color = stripSharp p.rosewater.hex;
            selection-background = stripSharp p.surface2.hex;
            selection-foreground = stripSharp p.text.hex;
          };
        in
        {
          "catppuccin-${palette.light-flavor}" = toTheme palette.light-palette;
          "catppuccin-${palette.dark-flavor}" = toTheme palette.dark-palette;
        };
    };
  };
}