1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144
145. 145
146. 146
147. 147
148. 148
149. 149
150. 150
151. 151
152. 152
153. 153
154. 154
155. 155

# Copyright 2025 Shota FUJI <pockawoooh@gmail.com>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
# REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
# AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
# INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
# LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
# OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
# PERFORMANCE OF THIS SOFTWARE.
#
# SPDX-License-Identifier: 0BSD
#
# > Highly customizable Wayland bar for Sway and Wlroots based compositors
# https://github.com/alexays/waybar

{
  config,
  lib,
  pkgs,
  ...
}:
let
  waybar-text = pkgs.callPackage ../../../programs/waybar-text { };

  light = config.palette.rose-pine.variants.${config.palette.rose-pine.light-variant};
  dark = config.palette.rose-pine.variants.${config.palette.rose-pine.dark-variant};

  cfg = config.wayland-desktop.waybar;
in
{
  imports = [ ../palette/rose-pine.nix ];

  options.wayland-desktop.waybar.soundSystem = lib.mkOption {
    type = lib.types.enum [
      "pulseaudio"
      "pipewire"
    ];
    default = "pipewire";
  };

  config = {
    programs.waybar = {
      enable = true;

      settings = {
        main = {
          layer = "top";
          position = "bottom";

          modules-left = [ "custom/todo" ];
          modules-right = [
            "clock"
            (if (cfg.soundSystem == "pulseaudio") then "pulseaudio" else "wireplumber")
            "tray"
          ];

          clock = {
            # waybar can't read $TZ. Maybe a bug with Nix environment?
            timezone = "Asia/Tokyo";
            locale = "en_US.UTF-8";
            format = "{:%Y-%m-%d %H:%M}";
          };

          pulseaudio = lib.mkIf (cfg.soundSystem == "pulseaudio") {
            format = "{icon} {volume}% / {format_source}";
            format-muted = "muted {format_source}";

            on-click = "pavucontrol";
          };

          wireplumber = lib.mkIf (cfg.soundSystem == "pipewire") {
            format = "{icon} {volume}% / {format_source}";
            format-muted = "muted {format_source}";

            on-click = lib.getExe pkgs.pwvucontrol;
          };

          "custom/todo" = {
            exec = "${waybar-text}/bin/,waybar-text --trim-md-list ${config.xdg.dataHome}/todo.md";
            restart-interval = 10;
            return-type = "json";
            escape = true;
          };
        };
      };
    };

    # waybar module provided by Home Manager lacks light / dark mode feature.
    xdg.configFile =
      let
        baseStyle = ''
          * {
            font-family: Roboto, Helvetica, Arial, sans-serif;
            font-size: 16px;
          }

          window#waybar {
            font-weight: bold;
          }

          .module {
            padding: 2px 4px;
            margin: 4px;

            border-radius: 3px;
          }

          #clock,
          #network,
          #pulseaudio,
          #tray {
            color: inherit;
          }
        '';
      in
      {
        "waybar/style-light.css".text = ''
          ${baseStyle}

          window#waybar {
            background-color: ${light.surface};
            color: ${light.text};
          }

          #tray {
            background-color: ${light.overlay};
          }

          #pulseaudio:hover {
            background-color: ${light.highlightLow};
          }
        '';

        "waybar/style-dark.css".text = ''
          ${baseStyle}

          window#waybar {
            background-color: ${dark.base};
            color: ${dark.text};
          }

          #tray {
            background-color: transparent;
          }

          #pulseaudio:hover {
            background-color: ${dark.highlightLow};
          }
        '';
      };
  };
}