/flake.nix at master

# Copyright 2023 Shota FUJI <pockawoooh@gmail.com>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
# REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
# AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
# INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
# LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
# OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
# PERFORMANCE OF THIS SOFTWARE.
#
# SPDX-License-Identifier: 0BSD

{
  description = "My system configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    agenix = {
      url = "github:yaxitech/ragenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Declarative disk partitioning tool and NixOS module.
    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    mac-app-util = {
      url = "github:hraban/mac-app-util";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixgl = {
      url = "github:nix-community/nixGL";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-colorizer.url = "github:nutsalhan87/nix-colorizer";

    plac = {
      url = "git+https://codeberg.org/pocka/plac-for-gtk4.git";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    timetracker = {
      url = "git+https://codeberg.org/pocka/timetracker.git";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    legit = {
      url = "git+https://tangled.org/pocka.jp/legit?ref=release/v1.2.0";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      home-manager,
      agenix,
      disko,
      mac-app-util,
      nixgl,
      nix-colorizer,
      plac,
      timetracker,
      legit,
    }:
    let
      availableSystems = [
        "aarch64-darwin"
        "x86_64-linux"
      ];

      overlays = [ (import ./overlays/atkinson-hyperlegible-next.nix) ];
    in
    {
      homeConfigurations =
        let
          mkHomeConfiguration =
            {
              # Platform (e.g. x86_64-linux)
              system,
              # Machine specific module setting
              module ? { },
            }:
            home-manager.lib.homeManagerConfiguration rec {
              pkgs = import nixpkgs { inherit system overlays; };
              modules = [ module ];
              extraSpecialArgs = {
                inherit
                  nix-colorizer
                  mac-app-util
                  nixgl
                  plac
                  timetracker
                  legit
                  ;
              };
            };
        in
        {
          dev-linux = mkHomeConfiguration {
            system = "x86_64-linux";
            module = ./modules/hm/profiles/linux-desktop.nix;
          };

          git-server = mkHomeConfiguration {
            system = "x86_64-linux";
            module = ./modules/hm/profiles/git-server.nix;
          };

          mbp-m1 = mkHomeConfiguration {
            system = "aarch64-darwin";
            module = ./modules/hm/profiles/macos.nix;
          };

          macmini-m1 = mkHomeConfiguration {
            system = "aarch64-darwin";
            module = ./modules/hm/profiles/macos.nix;
          };

          workerbee = mkHomeConfiguration {
            system = "x86_64-linux";
            module = ./modules/hm/profiles/workerbee.nix;
          };
        };

      nixosConfigurations =
        let
          mkNixosConfiguration =
            { system, module }:
            nixpkgs.lib.nixosSystem {
              inherit system;

              pkgs = import nixpkgs {
                inherit system overlays;

                config.allowUnfreePredicate =
                  pkg: builtins.elem (nixpkgs.lib.getName pkg) [ "cnijfilter2" ];
              };

              modules = [ module ];
              specialArgs = {
                inherit
                  nixpkgs
                  home-manager
                  agenix
                  disko
                  nix-colorizer
                  plac
                  timetracker
                  legit
                  ;
              };
            };
        in
        {
          workerbee = mkNixosConfiguration {
            system = "x86_64-linux";
            module = ./modules/nixos/profiles/workerbee.nix;
          };

          queenbee = mkNixosConfiguration {
            system = "x86_64-linux";
            module = ./modules/nixos/profiles/queenbee.nix;
          };
        };

      apps = builtins.listToAttrs (
        builtins.map (
          system:
          let
            pkgs = nixpkgs.legacyPackages.${system};
          in
          {
            name = system;
            value = {
              incus-import =
                let
                  bin = pkgs.writeShellApplication {
                    name = "incus-import";

                    text = ''
                      set +e
                      set -x

                      CONFIG_NAME=$1
                      SQUASHFS=$(nix build .#nixosConfigurations."$CONFIG_NAME".config.system.build.squashfs --no-link --print-out-paths)
                      METADATA=$(nix build .#nixosConfigurations."$CONFIG_NAME".config.system.build.metadata --no-link --print-out-paths)

                      incus image import --alias "pocka/$CONFIG_NAME/nixos" "$METADATA"/tarball/*.tar.xz "$SQUASHFS"/nixos-lxc-image-${system}.squashfs
                    '';
                  };
                in
                {
                  type = "app";
                  program = "${bin}/bin/incus-import";
                };

              zon2nix = {
                type = "app";
                program = pkgs.lib.getExe pkgs.zon2nix;
              };
            };
          }
        ) availableSystems
      );

      formatter = builtins.listToAttrs (
        builtins.map (
          system:
          let
            pkgs = nixpkgs.legacyPackages.${system};
          in
          {
            name = system;
            value = pkgs.buildFHSEnv {
              name = "fhs-dprint";
              targetPkgs =
                pkgs: with pkgs; [
                  dprint
                  zig
                  go
                  nixfmt
                ];
              runScript = "dprint fmt";
            };
          }
        ) availableSystems
      );

      devShells = builtins.listToAttrs (
        builtins.map (
          system:
          let
            pkgs = nixpkgs.legacyPackages.${system};
          in
          {
            name = system;
            value = {
              default = pkgs.mkShell {
                packages = with pkgs; [
                  reuse
                  zig_0_15
                  zls_0_15
                  go
                  gopls
                  dprint
                  nixfmt
                  mkpasswd
                  ragenix
                ];
              };
            };
          }
        ) availableSystems
      );
    };
}