1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126

// Copyright 2025 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

using GLib;

namespace TimeTracker.Model {
	public sealed class Model : Object {
		public ListStore active_timers { get; construct; }
		public ListStore stopped_timers { get; construct; }
		public Storage.Storage? storage { get; construct; }

		public Model(Storage.Storage? storage = null) {
			Object(
				active_timers: new ListStore(typeof (Timer)),
				stopped_timers: new ListStore(typeof (Timer)),
				storage: storage
			);
		}

		construct {
			if (storage != null) {
				try {
					var events = storage.load();

					foreach (var event in events) {
						update_internal(event);
					}
				} catch (Error error) {
					log(null, LEVEL_ERROR, @"Loading of events failed: $(error.message)");
				}
			}
		}

		// Since Vala's type narrowing is half baked, cast inside branch may or may not be narrowed
		// down. Explicit cast means compiler fails narrowing at that branch.
		public void update(Event.Event event) {
			if (storage != null) {
				storage.save.begin(event, (_obj, res) => {
					try {
						storage.save.end(res);
					} catch (Error error) {
						critical(@"Save failed: $(error.message)");
					}
				});
			}

			update_internal(event);
		}

		internal void update_internal(Event.Event event) {
			if (event is Event.TimerStarted) {
				var timer = new Timer(event.timer_id, event.title, event.created_at);
				active_timers.append(timer);
				return;
			}

			if (event is Event.TimerTitleChanged) {
				Event.TimerTitleChanged e = (Event.TimerTitleChanged) event;

				for (uint i = 0; i < active_timers.n_items; i++) {
					var timer = (Timer) active_timers.get_item(i);
					if (timer.id == e.timer_id) {
						timer.title = e.new_title;
						return;
					}
				}

				for (uint i = 0; i < stopped_timers.n_items; i++) {
					var timer = (Timer) stopped_timers.get_item(i);
					if (timer.id == e.timer_id) {
						timer.title = e.new_title;
						return;
					}
				}

				return;
			}

			if (event is Event.TimerStopped) {
				Event.TimerStopped e = (Event.TimerStopped) event;

				for (uint i = 0; i < active_timers.n_items; i++) {
					var timer = (Timer) active_timers.get_item(i);
					if (timer.id == e.timer_id) {
						active_timers.remove(i);
						timer.stopped_at = e.created_at;
						timer.is_stopped = true;
						stopped_timers.append(timer);
						return;
					}
				}

				return;
			}

			if (event is Event.TimerDeleted) {
				Event.TimerDeleted e = (Event.TimerDeleted) event;

				for (uint i = 0; i < active_timers.n_items; i++) {
					var timer = (Timer) active_timers.get_item(i);
					if (timer.id == e.timer_id) {
						active_timers.remove(i);
						return;
					}
				}

				for (uint i = 0; i < stopped_timers.n_items; i++) {
					var timer = (Timer) stopped_timers.get_item(i);
					if (timer.id == e.timer_id) {
						stopped_timers.remove(i);
						return;
					}
				}

				return;
			}

			info(@"Unknown event found: id=$(event.event_id)");
		}
	}
}