1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144
145. 145
146. 146
147. 147
148. 148
149. 149
150. 150
151. 151
152. 152
153. 153
154. 154
155. 155
156. 156
157. 157
158. 158
159. 159
160. 160
161. 161
162. 162

// Copyright 2025 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

using GLib;

namespace TimeTracker.Storage {
	public sealed class Local : Object, Storage {
		private LocalEnvelope? tail { get; set; default = null; }
		private LocalManifest manifest { get; set; }
		private File dir { get; set; }
		private File manifest_file { get; set; }

		private File events_dir {
			owned get {
				return dir.get_child(manifest.events_dir);
			}
		}

		// This is currently sync because Gio.Application's entry point (`activate`)
		// have to be sync. Implementing loading window or splash-like file-select
		// dialog is not worth the effort for this prototype.
		public static Local from_dir(File dir) throws Error {
			try {
				dir.make_directory();
			} catch (Error error) {
				if (!(error is IOError.EXISTS)) {
					throw error;
				}

				info(@"Initialized data directory at $(dir.get_parse_name())");
			}

			LocalManifest manifest;
			var manifest_file = dir.get_child("timetracker.manifest.json");
			try {
				manifest = read_manifest(manifest_file);
			} catch (Error error) {
				if (!(error is IOError.NOT_FOUND)) {
					throw error;
				}

				manifest = new LocalManifest();
				write_manifest(manifest_file, manifest);
				info(@"Created manifest file at $(manifest_file.get_parse_name())");
			}

			var events_dir = dir.get_child(manifest.events_dir);
			try {
				events_dir.make_directory();
			} catch (Error error) {
				if (!(error is IOError.EXISTS)) {
					throw error;
				}

				info(@"Initialized events directory at $(events_dir.get_parse_name())");
			}

			var storage = new Local() {
				dir = dir,
				manifest_file = manifest_file,
				manifest = manifest,
			};

			return storage;
		}

		private static LocalManifest read_manifest(File file) throws Error {
			var stream = file.read();

			var parser = new Json.Parser();
			parser.load_from_stream(stream);
			var node = parser.get_root();

			var manifest = Json.gobject_deserialize(typeof(LocalManifest), node) as LocalManifest;
			assert(manifest != null);

			return manifest;
		}

		private static void write_manifest(File file, LocalManifest manifest) throws Error {
			FileIOStream io;
			try {
				io = file.open_readwrite();
			} catch (Error error) {
				if (!(error is IOError.NOT_FOUND)) {
					throw error;
				}

				io = file.create_readwrite(NONE);
			}

			var stream = io.output_stream;

			var node = Json.gobject_serialize(manifest);

			var generator = new Json.Generator();
			generator.set_root(node);
			generator.to_stream(stream);
		}

		public Event.Event[] load() throws Error {
			if (manifest.tail == null) {
				return {};
			}

			return load_events(manifest.tail);
		}

		private Event.Event[] load_events(string tail_id) throws Error {
			var list = new List<Event.Event>();
			string? next_id = tail_id;

			while (next_id != null) {
				var envelope = load_envelope(next_id);
				if (manifest.tail == envelope.id) {
					tail = envelope;
				}
				list.prepend(envelope.parse_event());
				next_id = envelope.parent;
			}

			Event.Event[] result = {};
			result.resize((int) list.length());
			foreach (var event in list) {
				result[list.index(event)] = event;
			}

			return result;
		}

		private LocalEnvelope load_envelope(string id) throws Error {
			var file = events_dir.get_child(@"$(id).json");
			var stream = file.read();

			return LocalEnvelope.new_from_stream(stream);
		}

		public async void save(Event.Event event) throws Error {
			var envelope = new LocalEnvelope(event) {
				parent = tail != null ? tail.id : null,
			};

			var file = events_dir.get_child(@"$(event.event_id).json");
			var io = file.create_readwrite(NONE);
			var stream = io.output_stream;

			envelope.write_stream(stream);
			stream.close();

			tail = envelope;
			manifest.tail = event.event_id;
			write_manifest(manifest_file, manifest);

			return;
		}
	}
}