1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95

// Copyright 2025 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

using GLib;

namespace TimeTracker.Widget {
	private class TimerListRow : Gtk.Box {
		/**
		 * User requested to stop the timer.
		 */
		public signal void stop(Model.Timer timer);

		public Model.Timer? timer { get; set construct; }

		private Binding? timer_binding = null;
		private Gtk.Label title = new Gtk.Label("");
		private Gtk.Label elapsed = new Gtk.Label("--:--:--");
		private Gtk.Button stop_button = new Gtk.Button();

		construct {
			this.notify["timer"].connect(() => {
				if (timer_binding != null) {
					timer_binding.unbind();
					timer_binding = null;
				}

				if (timer != null) {
					stop_button.visible = true;

					timer_binding = timer.bind_property("title", title, "label", SYNC_CREATE);

					update_elapsed();

					if (!timer.is_stopped) {
						Timeout.add(1000, () => {
							update_elapsed();

							return !timer.is_stopped;
						});
					} else {
						stop_button.visible = false;
					}
				}
			});

			this.margin_top = 16;
			this.margin_bottom = this.margin_top;
			this.margin_start = 12;
			this.margin_end = this.margin_start;
			this.spacing = 8;

			var info_col = new Gtk.Box(VERTICAL, 4);
			info_col.hexpand = true;
			info_col.hexpand_set = true;

			title.halign = START;
			title.css_classes = { "heading" };
			info_col.append(title);

			elapsed.halign = START;
			elapsed.css_classes = { "numeric" };
			info_col.append(elapsed);

			this.append(info_col);

			stop_button.label = "Stop";
			stop_button.visible = false;
			stop_button.clicked.connect(() => {
				if (timer != null) {
					this.stop(timer);
				}
			});

			this.append(stop_button);
		}

		private void update_elapsed() {
			var start = new DateTime.from_unix_utc(timer.started_at);
			var end = timer.is_stopped ? new DateTime.from_unix_utc(timer.stopped_at) : new DateTime.now_utc();

			var diff = end.difference(start);

			elapsed.label = "%02d:%02d:%02d".printf(
				(int) (diff / TimeSpan.HOUR),
				(int) (diff / TimeSpan.MINUTE) % 60,
				(int) (diff / TimeSpan.SECOND) % 60
			);
		}
	}
}