1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76

// Copyright 2025 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

using GLib;

namespace TimeTracker.Widget {
	private class CalendarCell : Gtk.Box {
		public DateTime date { get; construct; }
		public Array<Model.Timer> timers { get; construct; }
		public bool dimmed { get; set; default = false; }

		private Gtk.Label date_label = new Gtk.Label("") {
			css_classes = { "caption-heading" },
			margin_top = 8,
		};

		private Gtk.Label count_label = new Gtk.Label("");

		public CalendarCell(DateTime date, Array<Model.Timer> timers) {
			Object(
				date: date,
				timers: timers,
				orientation: Gtk.Orientation.VERTICAL,
				spacing: 4
			);
		}

		construct {
			this.add_css_class("card");

			this.notify["dimmed"].connect(() => {
				if (this.dimmed) {
					date_label.add_css_class("dimmed");
				} else {
					date_label.remove_css_class("dimmed");
				}
			});

			date_label.label = @"$(date.get_day_of_month())";
			this.append(date_label);

			for (uint i = 0; i < 3; i++) {
				var label = new Gtk.Label("") {
					css_classes = { "caption" },
					ellipsize = END,
					single_line_mode = true,
					margin_start = 6,
					margin_end = 6,
					xalign = 0,
				};
				if (i < timers.length && timers.data[i] != null) {
					label.label = timers.data[i].title;
				}
				this.append(label);
			}

			var more_label = new Gtk.Label("") {
				css_classes = { "caption", "dimmed" },
				single_line_mode = true,
				margin_start = 6,
				margin_end = 6,
				margin_bottom = 8,
				xalign = 1,
			};
			if (timers.length > 3) {
				more_label.label = @"...$(timers.length - 3) more";
			}
			this.append(more_label);
		}
	}
}