1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114

// Copyright 2025 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.
//
// SPDX-License-Identifier: MPL-2.0

using GLib;

namespace TimeTracker.Widget {
	private class TimerListRow : Gtk.Box {
		/**
		 * User requested to stop the timer.
		 */
		public signal void stop(Model.Timer timer);

		/**
		 * User requested to edit the timer.
		 */
		public signal void edit(Model.Timer timer);

		public Model.Timer? timer { get; set construct; }

		private Binding? timer_binding = null;

		private Gtk.Label title = new Gtk.Label("") {
			ellipsize = END,
			halign = START,
			css_classes = { "heading" },
		};

		private TimeSpan elapsed = new TimeSpan() {
			halign = START,
			css_classes = { "numeric" },
			compact = true,
		};

		private Adw.SplitButton actions = new Adw.SplitButton() {
			valign = START,
			label = "Stop",
		};

		construct {
			this.notify["timer"].connect(() => {
				if (timer_binding != null) {
					timer_binding.unbind();
					timer_binding = null;
				}

				if (timer != null) {
					timer_binding = timer.bind_property("title", title, "label", SYNC_CREATE);

					update_elapsed();

					if (!timer.is_stopped) {
						Timeout.add(1000, () => {
							update_elapsed();

							return !timer.is_stopped;
						});
					}
				}
			});

			this.margin_top = 16;
			this.margin_bottom = this.margin_top;
			this.margin_start = 12;
			this.margin_end = this.margin_start;
			this.spacing = 8;

			var info_col = new Gtk.Box(VERTICAL, 4) {
				hexpand = true,
				hexpand_set = true,
			};

			info_col.append(title);
			info_col.append(elapsed);

			this.append(info_col);

			var action_group = new SimpleActionGroup();

			var edit_action = new SimpleAction("Edit", null);
			edit_action.activate.connect(() => {
				if (timer != null) {
					this.edit(timer);
				}
			});
			action_group.add_action(edit_action);

			this.insert_action_group("ActiveTimerActions", action_group);

			var menu = new Menu();
			menu.append("Edit", "ActiveTimerActions.Edit");
			actions.menu_model = menu;

			actions.clicked.connect(() => {
				if (timer != null) {
					this.stop(timer);
				}
			});

			this.append(actions);
		}

		private void update_elapsed() {
			var start = new DateTime.from_unix_utc(timer.started_at);
			var end = timer.is_stopped ? new DateTime.from_unix_utc(timer.stopped_at) : new DateTime.now_utc();

			elapsed.span = end.difference(start);
		}
	}
}