1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133

# SPDX-License-Identifier: AGPL-3.0-only
# Copyright 2025 Shota FUJI
#
# This program is free software: you can redistribute it and/or modify it under the terms
# of the GNU Affero General Public License as published by the Free Software Foundation,
# either version 3 of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
# PARTICULAR PURPOSE.  See the GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License along
# with this program.  If not, see <http://www.gnu.org/licenses/>.

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        deploy-docs = pkgs.callPackage ./tools/deploy-docs { };
      in
      rec {
        packages = {
          docs = pkgs.callPackage ./docs/package.nix { };
        };

        apps = {
          # nix run .#docs
          # --------------
          # ドキュメントの開発サーバを起動する。オプションは "--" の後に指定する。
          # 例: nix run .#docs -- --help
          docs =
            let
              server = pkgs.symlinkJoin {
                name = "server-docs";

                nativeBuildInputs = [ pkgs.makeWrapper ];

                paths = [
                  (pkgs.python3.withPackages (
                    python: with python; [
                      python.mkdocs
                      python.mkdocs-material
                    ]
                  ))
                ];

                postBuild = ''
                  wrapProgram $out/bin/mkdocs \
                    --add-flags 'serve' \
                    --add-flags '--config-file' \
                    --add-flags 'docs/mkdocs.yml'
                '';
              };
            in
            {
              type = "app";
              program = "${server}/bin/mkdocs";
            };

          # nix run .#deploy-docs
          # ---------------------
          # ドキュメントをビルドしてデプロイをする。
          # リポジトリルートから実行する必要がある。
          # "docs/" で Tofu を実行して環境をセットアップしていないと失敗する。
          deploy-docs =
            let
              cmd = pkgs.symlinkJoin {
                name = "deploy-docs-wrapped";

                nativeBuildInputs = [
                  pkgs.makeWrapper
                  packages.docs
                ];

                paths = [ deploy-docs ];

                postBuild = ''
                  wrapProgram $out/bin/deploydocs \
                    --add-flags '-dir' \
                    --add-flags ${packages.docs} \
                    --add-flags '-tf-dir' \
                    --add-flags 'docs'
                '';
              };
            in
            {
              type = "app";
              program = "${cmd}/bin/deploydocs";
            };
        };

        devShell = pkgs.mkShell {
          packages =
            with pkgs;
            [
              # Code formatting platform written in Rust
              # https://dprint.dev/
              dprint

              # Official formatter for Nix code
              # https://hackage.haskell.org/package/nixfmt
              nixfmt-rfc-style

              # Copyright and license linter based on SPDX
              # https://github.com/fsfe/reuse-tool
              reuse

              # Go Programming language
              # https://go.dev/
              go

              # Official language server for the Go language
              # https://github.com/golang/tools/tree/master/gopls
              gopls
            ]
            ++ deploy-docs.buildInputs;
        };
      }
    );
}