1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104

// SPDX-License-Identifier: MPL-2.0
// Copyright 2026 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.

const std = @import("std");

const yamori = @import("yamori");
const auth = yamori.authorization;

fn isAdmin(user: *const auth.User(Attributes)) bool {
    return user.attributes.@"管理者";
}

fn isHR(user: *const auth.User(Attributes)) bool {
    return user.attributes.@"部署" == .@"人事部";
}

fn isDeptBoss(user: *const auth.User(Attributes)) bool {
    if (user.attributes.@"部署" == null) {
        return false;
    }

    const @"役職" = user.attributes.@"役職" orelse return false;
    return std.mem.eql(u8, @"役職", "部長");
}

fn isSameDept(a: *const auth.User(Attributes), b: *const auth.User(Attributes)) bool {
    return a.attributes.@"部署" == b.attributes.@"部署";
}

fn allowCreateUser(operator: *const auth.User(Attributes)) bool {
    return isAdmin(operator) or isHR(operator);
}

fn allowDeleteUser(operator: *const auth.User(Attributes), target: *const auth.User(Attributes)) bool {
    if (isAdmin(operator)) {
        return true;
    }

    if (isAdmin(target)) {
        return false;
    }

    if (isHR(operator)) {
        return true;
    }

    if (isSameDept(operator, target) and isDeptBoss(operator)) {
        return true;
    }

    return false;
}

fn allowUpdateUserAttribute(
    operator: *const auth.User(Attributes),
    target: *const auth.User(Attributes),
    new_value: auth.AttributeUpdate(Attributes),
) bool {
    if (isAdmin(operator)) {
        return true;
    }

    return switch (new_value) {
        .@"管理者" => false,
        // 所属部署変更は人事部のみ許可
        .@"部署" => isHR(operator),
        .@"役職" => {
            if (isHR(operator)) {
                return true;
            }

            if (isSameDept(operator, target) and isDeptBoss(operator)) {
                return true;
            }

            return false;
        },
    };
}

const Attributes = struct {
    @"管理者": bool,
    @"部署": ?enum {
        @"人事部",
        @"経理部",
        @"法務部",
    } = null,
    @"役職": ?[]const u8 = null,
};

pub fn main(init: std.process.Init) !void {
    const handlers: auth.Handlers(Attributes) = .{
        .create_user = &allowCreateUser,
        .delete_user = &allowDeleteUser,
        .update_user_attribute = &allowUpdateUserAttribute,
    };

    const Server = yamori.Server(Attributes);
    try Server.run(init, &handlers);
}