1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128

// SPDX-License-Identifier: MPL-2.0
// Copyright 2026 Shota FUJI
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at https://mozilla.org/MPL/2.0/.

const std = @import("std");

pub const authorization = @import("./authorization.zig");

pub fn Server(comptime UserAttributes: type) type {
    return struct {
        pub const RunError = std.Io.Writer.Error;

        pub fn run(init: std.process.Init, handlers: *const authorization.Handlers(UserAttributes)) RunError!void {
            _ = handlers;

            const stdout = std.Io.File.stdout();
            defer stdout.close(init.io);

            var writer_buf: [1024]u8 = undefined;
            var writer = stdout.writer(init.io, &writer_buf);

            try std.json.fmt(AttrDef(UserAttributes){}, .{}).format(&writer.interface);
            try writer.interface.writeByte('\n');

            try writer.interface.flush();
        }
    };
}

fn AttrDef(comptime T: type) type {
    const t = switch (@typeInfo(T)) {
        .@"struct" => |str| str,
        else => |t| {
            @compileError(std.fmt.comptimePrint("AttrDef only accepts struct, got {t}", .{t}));
        },
    };

    return struct {
        fn writeType(comptime R: type, comptime field: []const u8, jws: *std.json.Stringify) !void {
            switch (@typeInfo(R)) {
                .int => |int| {
                    if (int.signedness == .unsigned) {
                        @compileError(std.fmt.comptimePrint("Integer attribute cannot be unsigned: {s}", .{field}));
                    }

                    if (int.bits > 52) {
                        @compileError(std.fmt.comptimePrint("Maximum integer size is 52bit: {s}", .{field}));
                    }

                    try jws.objectField("type");
                    try jws.write("int");
                },
                .float => |float| {
                    if (float.bits > 52) {
                        @compileError(std.fmt.comptimePrint("Maximum float size is 52bit: {s}", .{field}));
                    }

                    try jws.objectField("type");
                    try jws.write("float");
                },
                .bool => {
                    try jws.objectField("type");
                    try jws.write("bool");
                },
                .pointer => |pointer| {
                    if (!pointer.is_const or pointer.child != u8 or pointer.size != .slice) {
                        @compileError(std.fmt.comptimePrint("Only supported pointer is []const u8: {s}", .{field}));
                    }

                    try jws.objectField("type");
                    try jws.write("string");
                },
                .@"enum" => |e| {
                    try jws.objectField("type");
                    try jws.write("enum");

                    try jws.objectField("options");
                    try jws.beginArray();
                    inline for (e.fields) |f| {
                        try jws.beginObject();

                        try jws.objectField("name");
                        try jws.write(f.name);

                        try jws.objectField("value");
                        try jws.write(f.value);

                        try jws.endObject();
                    }
                    try jws.endArray();
                },
                else => {
                    @compileError(std.fmt.comptimePrint("Unsupported attribute value type at {s}: {t}", .{ field, @typeInfo(T) }));
                },
            }
        }

        pub fn jsonStringify(_: @This(), jws: *std.json.Stringify) !void {
            try jws.beginArray();

            inline for (t.fields) |field| {
                try jws.beginObject();

                try jws.objectField("key");
                try jws.write(field.name);

                switch (@typeInfo(field.type)) {
                    .optional => |optional| {
                        try jws.objectField("optional");
                        try jws.write(true);

                        try writeType(optional.child, field.name, jws);
                    },
                    else => {
                        try writeType(field.type, field.name, jws);
                    },
                }

                try jws.endObject();
            }

            try jws.endArray();
        }
    };
}