/flake.nix at 88f322e49e901b9ec916a5df45ac1fab8ae27b3e

# SPDX-License-Identifier: AGPL-3.0-only
# Copyright 2025 Shota FUJI
#
# This program is free software: you can redistribute it and/or modify it under the terms
# of the GNU Affero General Public License as published by the Free Software Foundation,
# either version 3 of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
# PARTICULAR PURPOSE.  See the GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License along
# with this program.  If not, see <http://www.gnu.org/licenses/>.

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    mkElmDerivation = {
      url = "github:jeslie0/mkElmDerivation";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      mkElmDerivation,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          overlays = [ mkElmDerivation.overlays.default ];
          inherit system;
        };
      in
      rec {
        packages = {
          demo = pkgs.callPackage ./demo { };
          docs = pkgs.callPackage ./docs/package.nix { };
        };

        formatter = pkgs.buildFHSEnv {
          name = "fhs-dprint";
          runScript = "dprint fmt";

          targetPkgs =
            pkgs: with pkgs; [
              # Code formatting platform written in Rust
              # https://dprint.dev/
              dprint

              # > A source code formatter for Elm
              # https://github.com/avh4/elm-format
              elmPackages.elm-format

              # Official formatter for Nix code
              # https://github.com/NixOS/nixfmt
              nixfmt

              # Tool for building, changing, and versioning infrastructure
              # https://opentofu.org/
              opentofu

              zig
            ];
        };

        apps =
          let
            deploy = dir: {
              type = "app";
              program = pkgs.lib.getExe (
                pkgs.writeShellApplication {
                  name = "deploy-${dir}";

                  text = ''
                    CF_DIST_ID=$(tofu -chdir=${dir} output -json | jq -r ".cloudfront_distribution_id.value")
                    S3_BUCKET_NAME=$(tofu -chdir=${dir} output -json | jq -r ".s3_bucket_name.value")

                    rclone sync \
                      ${packages.${dir}} \
                      ":s3:$S3_BUCKET_NAME" \
                      --s3-provider=AWS \
                      --s3-env-auth \
                      --s3-region="$AWS_DEFAULT_REGION" \
                      --checksum

                    aws cloudfront create-invalidation \
                      --distribution-id "$CF_DIST_ID" --paths '/*'
                  '';

                  runtimeInputs = with pkgs; [
                    packages.${dir}

                    # Tool for building, changing, and versioning infrastructure
                    # https://opentofu.org/
                    opentofu

                    # Unified tool to manage your AWS services
                    # https://aws.amazon.com/cli/
                    awscli2

                    # Lightweight and flexible command-line JSON processor
                    # https://jqlang.github.io/jq/
                    jq

                    # Command line program to sync files and directories to and from major cloud storage
                    # https://rclone.org/
                    rclone
                  ];
                }
              );
            };
          in
          {
            # nix run .#docs
            # --------------
            # ドキュメントの開発サーバを起動する。オプションは "--" の後に指定する。
            # 例: nix run .#docs -- --help
            docs =
              let
                server = pkgs.symlinkJoin {
                  name = "server-docs";

                  nativeBuildInputs = [ pkgs.makeWrapper ];

                  paths = [
                    (pkgs.python3.withPackages (
                      python: with python; [
                        python.mkdocs
                        python.mkdocs-material
                      ]
                    ))
                  ];

                  postBuild = ''
                    wrapProgram $out/bin/mkdocs \
                      --add-flags 'serve' \
                      --add-flags '--config-file' \
                      --add-flags 'docs/mkdocs.yml'
                  '';
                };
              in
              {
                type = "app";
                program = "${server}/bin/mkdocs";
              };

            # nix run .#deploy-docs
            # ---------------------
            # ドキュメントをビルドしてデプロイをする。
            # リポジトリルートから実行する必要がある。
            # "docs/" で Tofu を実行して環境をセットアップしていないと失敗する。
            deploy-docs = deploy "docs";

            # nix run .#deploy-demo
            # ---------------------
            # デモをビルドしてデプロイをする。
            # リポジトリルートから実行する必要がある。
            # "demo/" で Tofu を実行して環境をセットアップしていないと失敗する。
            deploy-demo = deploy "demo";

            tf = {
              type = "app";
              program = pkgs.lib.getExe pkgs.opentofu;
            };
          };

        devShell = pkgs.mkShell {
          packages =
            with pkgs;
            [
              # Code formatting platform written in Rust
              # https://dprint.dev/
              dprint

              # Official formatter for Nix code
              # https://github.com/NixOS/nixfmt
              nixfmt

              # Copyright and license linter based on SPDX
              # https://github.com/fsfe/reuse-tool
              reuse

              # > Language server implementation for Elm
              # https://github.com/elm-tooling/elm-language-server
              elmPackages.elm-language-server

              # > Zig LSP implementation + Zig Language Server
              # https://github.com/zigtools/zls
              zls

              # "demo" の "zig build serve" で利用する。
              # > Fast and extensible multi-platform HTTP/1-2-3 web server with automatic HTTPS
              # https://caddyserver.com/
              caddy
            ]
            ++ packages.demo.nativeBuildInputs;

          # "pkgs.zig" が $ZIG_GLOBAL_CACHE_DIR を本来設定すべきでない状況でも設定するバグにより
          # zig のコマンドが権限エラーで起動しなくなる。以前は zig.hook を除外するだけでよかった
          # が、 zig.hook を "pkgs.zig" に含める PR が件のバグを放置したまま取り込まれたため利用
          # 側で回避が必要となっている。
          # https://github.com/NixOS/nixpkgs/issues/270415
          # https://github.com/NixOS/nixpkgs/pull/473413
          shellHook = ''
            unset ZIG_GLOBAL_CACHE_DIR
          '';
        };
      }
    );
}