1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80

// SPDX-License-Identifier: AGPL-3.0-only
// Copyright 2026 Shota FUJI
//
// This program is free software: you can redistribute it and/or modify it under the terms
// of the GNU Affero General Public License as published by the Free Software Foundation,
// either version 3 of the License, or (at your option) any later version.
//
// This program is distributed in the hope that it will be useful, but WITHOUT ANY
// WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
// PARTICULAR PURPOSE.  See the GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License along
// with this program.  If not, see <http://www.gnu.org/licenses/>.

//! Elm ファイルを JS にコンパイルするモジュール。
//!
//! ```zig
//! // 利用例
//! const Elm = @import("./build/Elm.zig");
//!
//! const elm = Elm.init(b, .{
//!     .optimize = optimize,
//! });
//!
//! elm.addElmSourceFile(b.path("src/Main.elm"));
//!
//! const install_js = b.installFile(elm.output_js, "elm.js");
//! ```

const Elm = @This();

const std = @import("std");

elm_make: *std.Build.Step.Run,
output_js: std.Build.LazyPath,

const InitOptions = struct {
    /// 最適化モード。
    ///
    /// * `Debug`    ... Elm のデバッガー UI が有効になる。
    /// * `Release*` ... 出力される JS ファイルが最小化・最適化される。
    optimize: std.builtin.OptimizeMode,
};

pub fn init(b: *std.Build, opts: InitOptions) Elm {
    const elm_make = b.addSystemCommand(&.{ "elm", "make" });

    if (opts.optimize == .Debug) {
        elm_make.addArg("--debug");
    } else {
        elm_make.addArg("--optimize");
    }

    elm_make.expectExitCode(0);

    const output_js = elm_make.addPrefixedOutputFileArg("--output=", "elm.js");

    if (opts.optimize == .Debug) {
        return .{
            .elm_make = elm_make,
            .output_js = output_js,
        };
    } else {
        const closure_compiler = b.addSystemCommand(&.{"closure-compiler"});

        closure_compiler.addPrefixedFileArg("--js=", output_js);
        const minified_js = closure_compiler.addPrefixedOutputFileArg("--js_output_file=", "elm.min.js");

        return .{
            .elm_make = elm_make,
            .output_js = minified_js,
        };
    }
}

/// コンパイルする Elm のソースコードを追加する。
/// `main` のあるエントリーポイント以外のファイルも追加する必要がある。
pub fn addElmSourceFile(self: Elm, path: std.Build.LazyPath) void {
    self.elm_make.addFileArg(path);
}