1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106
107. 107
108. 108
109. 109
110. 110
111. 111
112. 112
113. 113
114. 114
115. 115
116. 116
117. 117
118. 118
119. 119
120. 120
121. 121
122. 122
123. 123
124. 124
125. 125
126. 126
127. 127
128. 128
129. 129
130. 130
131. 131
132. 132
133. 133
134. 134
135. 135
136. 136
137. 137
138. 138
139. 139
140. 140
141. 141
142. 142
143. 143
144. 144
145. 145
146. 146
147. 147
148. 148
149. 149
150. 150
151. 151
152. 152
153. 153
154. 154
155. 155
156. 156
157. 157
158. 158
159. 159
160. 160
161. 161
162. 162
163. 163
164. 164
165. 165
166. 166
167. 167
168. 168
169. 169
170. 170
171. 171
172. 172
173. 173
174. 174

// Copyright 2026 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
	[GtkTemplate(ui = "/jp/pocka/plac/gtk-adwaita/ui/preferences-dialog.ui")]
	private class PreferencesDialog : Adw.PreferencesDialog {
		private Settings settings = new Settings();

		[GtkChild]
		private unowned Adw.ComboRow startup_category;

		[GtkChild]
		private unowned Adw.SwitchRow disable_csd;

		[GtkChild]
		private unowned Adw.SwitchRow label_parsing_enabled;

		[GtkChild]
		private unowned Adw.SwitchRow show_browse_item_separators;

		[GtkChild]
		private unowned Adw.SwitchRow show_seek_by_10secs;

		[GtkChild]
		private unowned Adw.SwitchRow show_stop_button;

		[GtkChild]
		private unowned Adw.SwitchRow focus_browse_items_on_load;

		[GtkChild]
		private unowned Adw.EntryRow seek_step_size;

		[GtkChild]
		private unowned Adw.EntryRow seek_page_size;

		[GtkChild]
		private unowned Adw.SwitchRow fixed_discovery_udp_port_enabled;

		[GtkChild]
		private unowned Adw.EntryRow discovery_udp_port;

		public PreferencesDialog() {
			Object();
		}

		construct {
			var startup_category_factory = new Gtk.SignalListItemFactory();
			startup_category_factory.setup.connect(setup_startup_category);
			startup_category_factory.bind.connect(bind_startup_category);

			var startup_category_model = new Adw.EnumListModel(typeof (Roon.Browse.Hierarchy));

			startup_category.model = startup_category_model;
			startup_category.factory = startup_category_factory;

			settings.settings.bind_with_mapping(Settings.STARTUP_CATEGORY, startup_category, "selected", DEFAULT, (to, from, user_data) => {
				var model = (Adw.EnumListModel) user_data;

				var hierarchy = Roon.Browse.Hierarchy.from_int(from.get_int32());
				to.set_uint(model.find_position(hierarchy));
				return true;
			}, (from, variant_type, user_data) => {
				var model = (Adw.EnumListModel) user_data;

				var item = (Adw.EnumListItem) model.get_item(from.get_uint());
				if (item == null) {
					// Vala's type definition wrongly defines return type signature of
					// "SettingsBindSetMappingShared" as non-null, despite it being nullable and
					// even documentation saying "return null in case of an error."
					// This cast suppress compiler warning.
					return (Variant) null;
				}

				var hierarchy = Roon.Browse.Hierarchy.from_int(item.value);
				return new Variant("i", hierarchy);
			}, startup_category_model, null);

			settings.settings.bind(Settings.DISABLE_CSD, disable_csd, "active", DEFAULT);
			settings.settings.bind(Settings.LABEL_PARSING_ENABLED, label_parsing_enabled, "active", DEFAULT);
			settings.settings.bind(Settings.SHOW_BROWSE_ITEM_SEPARATORS, show_browse_item_separators, "active", DEFAULT);
			settings.settings.bind(Settings.SHOW_SEEK_BY_10SECS, show_seek_by_10secs, "active", DEFAULT);
			settings.settings.bind(Settings.SHOW_STOP_BUTTON, show_stop_button, "active", DEFAULT);

			settings.settings.bind(Settings.FOCUS_BROWSE_ITEMS_ON_LOAD, focus_browse_items_on_load, "active", DEFAULT);
			settings.settings.bind_with_mapping(Settings.SEEK_STEP_SIZE, seek_step_size, "text", DEFAULT, (to, from) => {
				var size = from.get_uint32();
				to.set_string(size.to_string());
				return true;
			}, (from, variant) => {
				var text = from.get_string();
				var raw_val = uint.parse(text, 10);
				if (raw_val == 0) {
					// Vala's type definition wrongly defines return type signature of
					// "SettingsBindSetMappingShared" as non-null, despite it being nullable and
					// even documentation saying "return null in case of an error."
					// This cast suppress compiler warning.
					return (Variant) null;
				}

				return new Variant("u", raw_val);
			}, null, null);
			settings.settings.bind_with_mapping(Settings.SEEK_PAGE_SIZE, seek_page_size, "text", DEFAULT, (to, from) => {
				var size = from.get_uint32();
				to.set_string(size.to_string());
				return true;
			}, (from, variant) => {
				var text = from.get_string();
				var raw_val = uint.parse(text, 10);
				if (raw_val == 0) {
					// Vala's type definition wrongly defines return type signature of
					// "SettingsBindSetMappingShared" as non-null, despite it being nullable and
					// even documentation saying "return null in case of an error."
					// This cast suppress compiler warning.
					return (Variant) null;
				}

				return new Variant("u", raw_val);
			}, null, null);

			settings.settings.bind_with_mapping(Settings.DISCOVERY_UDP_PORT, fixed_discovery_udp_port_enabled, "active", DEFAULT, (to, from) => {
				var port = from.get_uint32();
				to.set_boolean(port != 0);
				return true;
			}, (from, variant) => {
				return new Variant("u", from.get_boolean() ? 9003 : 0);
			}, null, null);
			settings.settings.bind_with_mapping(Settings.DISCOVERY_UDP_PORT, discovery_udp_port, "text", DEFAULT, (to, from) => {
				var port = from.get_uint32();
				to.set_string(port.to_string());
				return true;
			}, (from, variant) => {
				var text = from.get_string();
				var raw_val = uint.parse(text, 10);
				if (raw_val == 0 || raw_val > uint16.MAX) {
					// Vala's type definition wrongly defines return type signature of
					// "SettingsBindSetMappingShared" as non-null, despite it being nullable and
					// even documentation saying "return null in case of an error."
					// This cast suppress compiler warning.
					return (Variant) null;
				}

				return new Variant("u", raw_val);
			}, null, null);
			fixed_discovery_udp_port_enabled.bind_property("active", discovery_udp_port, "visible", SYNC_CREATE);
		}

		private static void setup_startup_category(Gtk.ListItemFactory factory, Object object) {
			var list_item = (Gtk.ListItem) object;
			list_item.child = new Gtk.Label("");
		}

		private static void bind_startup_category(Gtk.ListItemFactory factory, Object object) {
			var list_item = (Gtk.ListItem) object;
			var item = (Adw.EnumListItem) list_item.item;
			var hierarchy = Roon.Browse.Hierarchy.from_int(item.value);
			var label = (Gtk.Label) list_item.child;

			label.label = hierarchy.to_display_string();
		}
	}
}