1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62
63. 63
64. 64
65. 65
66. 66
67. 67
68. 68
69. 69
70. 70
71. 71
72. 72
73. 73
74. 74
75. 75
76. 76
77. 77
78. 78
79. 79
80. 80
81. 81
82. 82
83. 83
84. 84
85. 85
86. 86
87. 87
88. 88
89. 89
90. 90
91. 91
92. 92
93. 93
94. 94
95. 95
96. 96
97. 97
98. 98
99. 99
100. 100
101. 101
102. 102
103. 103
104. 104
105. 105
106. 106

// Copyright 2026 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
	[GtkTemplate(ui = "/jp/pocka/plac/gtk-adwaita/ui/direct-connect-dialog.ui")]
	class DirectConnectDialog : Adw.Dialog {
		public signal void submit(GLib.InetSocketAddress sock_addr);

		[GtkChild]
		private unowned Gtk.Entry ip_addr;

		[GtkChild]
		private unowned Gtk.Entry port;

		[GtkChild]
		private unowned Gtk.Button connect_button;

		public DirectConnectDialog() {
			Object();
		}

		construct {
			connect_button.clicked.connect(() => {
				var sock_addr = get_sock_addr();
				if (sock_addr != null) {
					submit(sock_addr);
				}
			});
		}

		/**
		 * Returns `null` if any field has invalid (un-parsable) input text.
		 */
		private GLib.InetSocketAddress? get_sock_addr() {
			GLib.InetAddress? a = null;
			uint16? p = null;

			a = parse_ip_addr();
			p = parse_port();

			if (a == null) {
				ip_addr.tooltip_text = "Must be valid IPv4 or IPv6 address, without port number";
				ip_addr.add_css_class("error");
				ip_addr.update_state(Gtk.AccessibleState.INVALID, Gtk.AccessibleInvalidState.TRUE, -1);
			} else {
				ip_addr.tooltip_text = "";
				ip_addr.remove_css_class("error");
				ip_addr.reset_state(Gtk.AccessibleState.INVALID);
			}

			if (p == null) {
				port.tooltip_text = "Must be valid port number";
				port.add_css_class("error");
				port.update_state(Gtk.AccessibleState.INVALID, Gtk.AccessibleInvalidState.TRUE, -1);
			} else {
				port.tooltip_text = "";
				port.remove_css_class("error");
				port.reset_state(Gtk.AccessibleState.INVALID);
			}

			if (a == null || p == null) {
				return null;
			}

			return new GLib.InetSocketAddress(a, p);
		}

		/**
		 * Returns `null` if the input text is not valid IP address.
		 */
		private GLib.InetAddress? parse_ip_addr() {
			var value = ip_addr.text.strip();

			return new GLib.InetAddress.from_string(value);
		}

		/**
		 * Returns `null` if the input text is not valid port number.
		 */
		private uint16? parse_port() {
			try {
				var value = port.text.strip();
				uint64 n = 0;
				uint64.from_string(value, out n, 10, uint16.MIN, uint16.MAX);

				// "uint64.from_string" checks value range.
				return (uint16)n;
			} catch {
				return null;
			}
		}
	}
}