1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62

// Copyright 2026 Shota FUJI
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//
// SPDX-License-Identifier: Apache-2.0

namespace PlacGtkAdwaita {
	class ConfigurableShortcut : GLib.Object {
		public Gtk.Shortcut shortcut { get; construct; }
		public string setting_key { get; construct; }

		private Settings settings = new Settings();

		public ConfigurableShortcut(string setting_key, Gtk.ShortcutAction action) {
			var shortcut = new Gtk.Shortcut(Gtk.NeverTrigger.get(), action);
			Object(setting_key: setting_key, shortcut: shortcut);
		}

		// This constructor sets "NothingAction" at initialization, assuming caller configures an action
		// later on. This is for "CallbackAction", where instantiation on class initializer is impossible
		// due to closure's userdata capture.
		public ConfigurableShortcut.lazy(string setting_key) {
			var shortcut = new Gtk.Shortcut(Gtk.NeverTrigger.get(), Gtk.NothingAction.get());
			Object(setting_key: setting_key, shortcut: shortcut);
		}

		construct {
			configure();

			settings.settings.changed[setting_key].connect(() => {
				configure();
			});
		}

		private void configure() {
			var accelerator = settings.settings.get_string(setting_key);
			if (accelerator == null || accelerator == "") {
				shortcut.trigger = Gtk.NeverTrigger.get();
			} else {
				shortcut.trigger = Gtk.ShortcutTrigger.parse_string(accelerator);
			}
		}

		// Install shortcut to a widget. Mostly for "ActivateAction".
		public void install(Gtk.Widget widget, Gtk.ShortcutScope scope = MANAGED) {
			var controller = new Gtk.ShortcutController();
			controller.scope = scope;
			controller.add_shortcut(this.shortcut);
			widget.add_controller(controller);
		}
	}
}